이미지에 다각형 그리기

Question

나는이 동안 꽤 오랫동안 검색해 왔지만 대답을 얻을 수 없었다.

이미지에 다각형을 그리고 싶지만 점을 만들어서이 작업을하고 싶습니다. MouseCursor으로이 특정 점을 만들고 단추로이 점들을 따라 선을 그립니다. 이것은 내가 원하는,하지만 차이가 등이 MouseEvent와 사용자가 주어진다는 Point[1], Point[2]입니다

var 
    Poly: array of TPoint; 
begin 
    // Allocate dynamic array of TPoint 
    SetLength(Poly, 6); 

    // Set array elements 
    Poly[0] := Point(10, 10); 
    Poly[1] := Point(30, 5); 
    Poly[2] := Point(100, 20); 
    Poly[3] := Point(120, 100); 
    Poly[4] := Point(50, 120); 
    Poly[5] := Point(10, 60); 

    // Pass to drawing routine 
    Canvas.Polygon(Poly); 

    // Redim if needed 
    SetLength(Poly, 7); 
    Poly[6] := Point(1, 5); 

    // Pass to drawing routine 
    Canvas.Polygon(Poly); 
end; 

:

나는이 발견했다.

Answer 1

당신은 당신의 이미지를 통해 그림 물감을 중첩하고, 질문은 무엇입니까이

unit Unit3; 

interface 

uses 
    Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, 
    Dialogs, ExtCtrls, StdCtrls; 

type 
    TPointArray=array of TPoint; 
    TForm3 = class(TForm) 
    Image1: TImage; 
    PaintBox1: TPaintBox; 
    Button1: TButton; 
    procedure PaintBox1MouseDown(Sender: TObject; Button: TMouseButton; 
     Shift: TShiftState; X, Y: Integer); 
    procedure PaintBox1Paint(Sender: TObject); 
    procedure Button1Click(Sender: TObject); 
    private 
    { Private-Deklarationen } 
    FPointArray:TPointArray; 
    public 
    { Public-Deklarationen } 
    end; 
var 
    Form3: TForm3; 
implementation 
{$R *.dfm} 

procedure TForm3.Button1Click(Sender: TObject); 
begin 
    PaintBox1.Visible := false; 
    Image1.Canvas.Polygon(FPointArray); 
end; 

procedure TForm3.PaintBox1MouseDown(Sender: TObject; Button: TMouseButton; 
    Shift: TShiftState; X, Y: Integer); 
begin 
    SetLength(FPointArray,Length(FPointArray)+1); 
    FPointArray[High(FPointArray)].X := X; 
    FPointArray[High(FPointArray)].Y := Y; 
    Paintbox1.Invalidate; 
end; 

procedure TForm3.PaintBox1Paint(Sender: TObject); 
var 
i:Integer; 
begin 
    PaintBox1.Canvas.Brush.Style := bsClear; //as suggested by TLama 
    PaintBox1.Canvas.Polygon(FPointArray); 
    for I := 0 to High(FPointArray) do 
     begin 
     PaintBox1.Canvas.TextOut(FPointArray[i].X-5,FPointArray[i].y-5,IntToStr(i)); 
     end; 
end; 

end. 

Answer 2

양식에 의해 관리되는 점의 배열을 만듭니다. 양식 클래스에서 동적 배열 필드를 선언 : 당신의 OnClick 경우

private 
    FPoly: array of TPoint; 

를 배열을 연장하고 새로운를 추가 그것에 좌표,

procedure TFruitForm.ImageClick(Sender: TObject); 
var 
    p: TPoint; 
begin 
    p := ...; 
    SetLength(FPoly, Length(FPoly) + 1); 
    FPoly[High(FPoly)] := p; 
end; 

이 p를 할당하는 방법을 참조하십시오 How do I get the coordinates of the mouse when a control is clicked?

배열 대신 일반 목록 (TList<TPoint>)을 사용해보십시오.