배치 파일을 사용하여 여러 파일 만들기

Question

안녕하세요 누구든지이 문제에서 나를 도울 수 있습니까?

여러 파일을 생성해야합니까 ?? 나는 모든 예를 든다. 어떤 폴더에서는 폴더 레코드라고 말합니다. "Record"폴더에는 "example2tought1023.au"라는 이름의 파일이 1 개 있습니다. 내가 포함하는 동일한 파일을 생성해야합니다, 그냥 숫자를 늘려 여러 번.

내가 얻을 같은 결과를해야 example2tought1023.au example3tought1024.au example4tought1025.au example5tought1026.au

이 내가 현재 가지고있는된다

SET count=9 

SET filename_1=example 
SET filename_2=thought 

SET extension=.au 

SET start_1=2 
SET start_2=1023 

SET source=%filename_1%%start_1%%filename_2%%start_2%%extension% 

FOR /L %%i IN (1, 1, %count%) DO (
    REM These two lines do not work! 
    SET /a n=%start_1%+%%i 
    SET /a number_2=%start_2% + %%i 

    SET destination=%filename_1%%number_1%%filename_2%%number_2%%extension% 

    ECHO %destination% 
    REM COPY %source% %destination% 
) 

PAUSE 

을하지만 FOR /L 루프 라인이 작동하지 않습니다

Answer 1

어떤 라인이 작동하지 않는지 잘못 알았습니다 :-)

관련 문제 변수가 확장 될 때까지 기다립니다. 행을 파싱하면 백분율을 사용하는 일반적인 확장이 발생하고 괄호로 묶인 DO 절을 포함하여 전체 FOR 문은 한 번에 구문 분석됩니다. 그래서 다음 줄

SET destination=%filename_1%%number_1%%filename_2%%number_2%%extension% 

는의 값을보고있다 % NUMBER_1 %와 % 숫자 2 % 루프가 실행 된 전에 를 존재하는. 분명히 당신이 원하는 것이 아닙니다. 솔루션은 간단합니다. 지연된 확장 (구문 분석 시간 대신 런타임에 값)을 사용해야합니다. 당신은 setlocal enableDelayedExpansion을 사용하여 1 차 확장 확장을 활성화 한 다음 %number_1% 대신 !number_1!을 사용합니다.

변수 이름 (n vs number_1)과 일치하지 않습니다.

나는 1에서 카운트하는 대신 0에서 카운트 -1까지 카운트하려고한다고 생각합니다.

SET/A 식에서 변수를 사용할 때 변수를 명시 적으로 확장 할 필요가 없습니다. 퍼센트 또는 느낌표없이 변수 이름을 간단하게 사용할 수 있습니다. 그러나 이것은 SET/A 명령에서만 작동합니다.

각 할당 사이에 쉼표를 사용하여 단일 SET/A 명령으로 여러 계산 및 할당을 수행 할 수도 있습니다.

@echo off 
setlocal enableDelayedExpansion 

REM counts from 0 to count, so 8 = 9 copies 
set count=8 

set filename_1=example 
set filename_2=thought 

set extension=.au 

set start_1=2 
set start_2=1023 

set source=%filename_1%%start_1%%filename_2%%start_2%%extension% 

for /L %%i in (0, 1, %count%) do (
    set /a "number_1=start_1+%%i, number_2=start_2+%%i" 
    set destination=%filename_1%!number_1!%filename_2%!number_2!%extension% 
    echo !destination! 
    REM copy %source% !destination! 
) 

pause