업데이트 중첩 된 구조는

Question

이 같은지도의 벡터지도를 가지고있다.

이제 태그 값을보고 :metrics을 id으로 업데이트하고 싶습니다.

예 : ["a tag"]가 ID 2로 예를 들어, ID 1과 일치하고, ["a noether tag" "aegn"] 있다면 업데이트 된 구조는 다음과 같이 할 : 내가 ID에 태그를 변환 할 수있는 기능 transform했다

{:tags ["type:something" "gw:somethingelse"], 
:sources [{:tags ["s:my:tags"], 
      :metrics [{:tags ["a tag"] 
         :id  1} 
         {:tags ["a noether tag" "aegn"] 
         :id  2} 
         {:tags ["eare" "rh"]}]}]} 

. 예 : (transform "a tag")은 1을 반환합니다. 이제는 이해를 위해 ID를 추가하려고 할 때 이전 구조 (내적 요소 만 반환 됨)가 누락되어서 assoc-in으로 색인을 미리 알아야합니다.

이 변환을 어떻게 우아하게 수행 할 수 있습니까?

Answer 1

변환 기능을 :tags에 입력 한 다음 :metrics을 입력 한 다음 :sources을 입력하면됩니다. 이제 우리는 단지 태그를 계산하여 기능 ID를 생성 변환 가정 해 봅시다

는

(단지 그림을 위해, 나중에 쉽게 변경 될 수 있습니다) : 지금

(defn transform-metric [{:keys [tags] :as m}] 
    (assoc m :id (transform tags))) 

user> (transform-metric {:tags ["a noether tag" "aegn"]}) 
;;=> {:tags ["a noether tag" "aegn"], :id 2} 

:

(defn transform [tags] (count tags)) 

user> (transform ["asd" "dsf"]) 
;;=> 2 

다음 변환에게 통계 항목을 적용 소스 항목을 업데이트하려면 transform-metric을 사용하십시오.

(defn transform-source [s] 
    (update s :metrics #(mapv transform-metric %))) 

user> (transform-source {:tags ["s:my:tags"], 
         :metrics [{:tags ["a tag"]} 
            {:tags ["a noether tag" "aegn"]} 
            {:tags ["eare" "rh"]}]}) 

;;=> {:tags ["s:my:tags"], 
;; :metrics [{:tags ["a tag"], :id 1} 
;;    {:tags ["a noether tag" "aegn"], :id 2} 
;;    {:tags ["eare" "rh"], :id 2}]} 

및 마지막 단계는 전체 데이터를 변환하는 것입니다 :

(defn transform-data [d] 
    (update d :sources #(mapv transform-source %))) 

user> (transform-data data) 
;;=> {:tags ["type:something" "gw:somethingelse"], 
;; :sources [{:tags ["s:my:tags"], 
;;    :metrics [{:tags ["a tag"], :id 1} 
;;       {:tags ["a noether tag" "aegn"], :id 2} 
;;       {:tags ["eare" "rh"], :id 2}]}]} 

그래서 여기서 끝났습니다.

지금 transform-data 및 transform-source 거의 동일하다는 것을 발견, 그래서 우리는 업데이트 기능을 생성하는 유틸리티 기능을 할 수 있습니다 : 우리는 다음과 같이 깊은 변환을 정의 할 수 있습니다이 기능을

(defn make-vec-updater [field transformer] 
    (fn [data] (update data field (partial mapv transformer)))) 

을 :

(def transformer 
    (make-vec-updater 
    :sources 
    (make-vec-updater 
    :metrics 
    (fn [{:keys [tags] :as m}] 
     (assoc m :id (transform tags)))))) 

user> (transformer data) 
;;=> {:tags ["type:something" "gw:somethingelse"], 
;; :sources [{:tags ["s:my:tags"], 
;;    :metrics [{:tags ["a tag"], :id 1} 
;;       {:tags ["a noether tag" "aegn"], :id 2} 
;;       {:tags ["eare" "rh"], :id 2}]}]} 

이 트랜스포머 구성 방법을 기반으로 우리는 vector of-maps-of-vectors-of-vectors의 값을 업데이트하는 멋진 함수를 만들 수 있습니다 ...임의의 중첩 수준과 구조 :

(defn update-in-v [data ks f] 
    ((reduce #(make-vec-updater %2 %1) f (reverse ks)) data)) 

user> (update-in-v data [:sources :metrics] 
        (fn [{:keys [tags] :as m}] 
        (assoc m :id (transform tags)))) 

;;=> {:tags ["type:something" "gw:somethingelse"], 
;; :sources [{:tags ["s:my:tags"], 
;;    :metrics [{:tags ["a tag"], :id 1} 
;;       {:tags ["a noether tag" "aegn"], :id 2} 
;;       {:tags ["eare" "rh"], :id 2}]}]} 

UPDATE

이 매뉴얼 방식뿐만 아니라, 정확히 같은 일을 (그리고 더 많은) 거기 specter라는 환상적인 LIB가있다, 하지만 분명 더 보편적이고 사용할 수 :

(require '[com.rpl.specter :as sp]) 

(sp/transform [:sources sp/ALL :metrics sp/ALL] 
       (fn [{:keys [tags] :as m}] 
       (assoc m :id (transform tags))) 
       data) 

;;=> {:tags ["type:something" "gw:somethingelse"], 
;; :sources [{:tags ["s:my:tags"], 
;;    :metrics [{:tags ["a tag"], :id 1} 
;;       {:tags ["a noether tag" "aegn"], :id 2} 
;;       {:tags ["eare" "rh"], :id 2}]}]} 

Answer 2

(use 'clojure.walk) 

(def transform {["a tag"]    1 
       ["a noether tag" "aegn"] 2}) 

(postwalk #(if-let [id (transform (:tags %))] 
      (assoc % :id id) 
      %) 
      data) 

출력 :

{:tags ["type:something" "gw:somethingelse"], 
:sources 
[{:tags ["s:my:tags"], 
    :metrics 
    [{:tags ["a tag"], :id 1} 
    {:tags ["a noether tag" "aegn"], :id 2} 
    {:tags ["eare" "rh"]}]}]}