Delphi에서 Outlook 2010 메일을 작성하는 가장 쉬운 방법은 무엇입니까?

Question

mailto:, simulated "Send To..." 및 SMTP를 Windows 2000 및 2003 환경에서 사용하는 다양한 전자 메일 통합 방법으로 잘 작동하는 일부 응용 프로그램은 이제 Exchange 2010 및 Outlook 2010 클라이언트가있는 새로운 Windows 2008 시스템으로 이동합니다.

응용 프로그램에서 새 메일을 만들고 수신자와 제목을 설정하고 하나 이상의 첨부 파일을 추가 한 다음 기본 메일 클라이언트에서 열어서 보내기 전에 사용자가 편집 할 수 있도록하는 유스 케이스가 하나 있습니다.

새로운 환경에서 작동하는 솔루션을 알고 계십니까? 제 3 자 라이브러리를 사용해야합니까? 또는 Outlook.Application을 사용하여 작동하는 것으로 알려진 OLE 자동화 코드가 있습니까?

Answer 1

우리는에 jclMapi 단위에서 JclSimpleBringUpSendMailDialog를 사용 제다이 JCL 라이브러리.

나는 SMTP 나 MAPI를 사용할지, 그리고 모든 종류의 메일 서버 설정을 사용 할지를 지정하기 위해 사용자 옵션을 빌드 한 적이 있지만 Jedi 라이브러리 호출을 사용하면 훨씬 쉽습니다. 최종 사용자가 MAPI 클라이언트에서 모든 설정을 구성하는 데 문제가 있다면 왜 내/우리 소프트웨어에서 다시 설정해야할까요?

mailto : // 문제는 메일 클라이언트가 동일한/표준 방식으로 매개 변수를 처리하지 못하는 경우가 종종 있습니다. 사용자는 소프트웨어가 쓰레기라고 생각하지 않고 소프트웨어가 쓰레기라고 생각합니다. dodgy 메일 클라이언트.

그래서 MAPI 인터페이스 만 사용합니다. 쉬운.

Answer 2

아마도 this can be useful for you.하지만 썬더 버드 사용자이기 때문에 테스트 할 수 없습니다.

Answer 3

나는이 예를 파헤쳤다. 그것은 2002 년 이후로 오래된 Outlook 버전을 사용하지만 아이디어는 여전히 같아야합니다. 그것은 새로 등록 된 사용자에게 자신의 아이디와 패스워드를 보내는 애플리케이션에서 사용되었습니다. (저를 시작하지 마십시오. 사이트에 대한 액세스를 제한하는 방법 이었지만 민감하지 않았습니다). 메시지는 열리지 않은 보낼 편지함에 저장되지만 OleServer 및 Outlook8을 통해 파고 들면 (숫자가 더 높아질 수 있음) 보낼 편지함에 바로 저장하는 대신 사용자의주의를 끌기 위해 메일을 열 수있는 방법을 찾아야합니다.

전체 Outlook 개체 모델

는 MSDN에서 찾을 수 있습니다 : http://msdn.microsoft.com/en-us/library/aa221870%28v=office.11%29.aspx

사무 자동화에 대한 자세한 내용은 또 다른 좋은 소스가 데보라 페이트의 페이지입니다 : http://www.djpate.freeserve.co.uk/Automation.htm

function TStapWerkt_data.GenerateMailsOutlook(SendDBF: boolean): boolean; 
var 
    Outlook: TOutlookApplication; 
    olNameSpace: NameSpace; 
    MailIt: TMailItem; 
    AttachedFile: OleVariant; 
    i: integer; 
    emailaddress: string; 
begin 
    Result := true; 
    Outlook := TOutlookApplication.Create(nil); 
    try 
    Outlook.ConnectKind := ckNewInstance; 
    try 
     Outlook.Connect; 
     try 
     olNameSpace := Outlook.GetNamespace('MAPI'); 
     olNameSpace.Logon('', '', False, False); 
     try 

      if SendDBF then begin 
      MailIt := TMailItem.Create(nil); 
      MailIt.ConnectTo(Outlook.CreateItem(olMailItem) as MailItem); 
      try 
       MailIt.Recipients.Add('info@bjmsoftware.com'); 
       MailIt.Subject := 'StapWerk.dbf'; 
       MailIt.Body := 'Stap'#13#10; 
       AttachedFile := IncludeTrailingBackslash(ExtractFilePath(
        Stap_db.Stap_Database.DatabaseName)) + 'stapwerk.dbf'; 
       MailIt.Attachments.Add(AttachedFile, EmptyParam, EmptyParam, EmptyParam); 
       MailIt.Save; 
      finally 
       MailIt.Free; 
      end; 
      end; 

      for i := 0 to FNewUsers.Count - 1 do begin 
      MailIt := TMailItem.Create(nil); 
      MailIt.ConnectTo(Outlook.CreateItem(olMailItem) as MailItem); 
      try 
       emailaddress := TStapper(FNewUsers.Items[i]).Email; 
       if emailaddress = '' then begin 
       emailaddress := C_MailUnknownAddress; 
       end; 
       MailIt.Recipients.Add(emailaddress); 
       MailIt.Subject := C_MailSubject; 
       MailIt.Body := Format(C_MailBody, 
        [TStapper(FNewUsers.Items[i]).UserId, 
        TStapper(FNewUsers.Items[i]).Password]); 
       MailIt.Save; 
      finally 
       MailIt.Free; 
      end; 
      end; 

     finally 
      olNameSpace.Logoff; 
     end; 
     finally 
     Outlook.Disconnect; 
     // We kunnen ondanks ckNewInstance quit niet gebruiken 
     // Outlook lijkt de connectkind te negeren en hoe dan ook te koppelen 
     // naar een bestaande instantie. En die gooi je dan dus ook dicht met quit. 
//  Outlook.quit; 
     end; 
    finally 
     Outlook.free; 
    end; 
    except 
    on E: Exception do begin 
     Result := false; 
    end; 
    end; 
end; 

Answer 4

내가 본 기기를 사용 -이 전 브라이언 긴 세 크레딧 ...

unit UArtMAPI; 


interface 



procedure ArtMAPISendMail(
      const Subject, MessageText, MailFromName, MailFromAddress, 
        MailToName, MailToAddress: String; 
      const AttachmentFileNames: array of String); 


implementation 



uses 
    SysUtils, 
    Windows, 
    UArtLibrary, 
    Dialogs, 
    Forms, 
    MAPI; 

procedure ArtMAPISendMail(
      const Subject, MessageText, MailFromName, MailFromAddress, 
        MailToName, MailToAddress: String; 
      const AttachmentFileNames: array of String); 
//Originally by Brian Long: The Delphi Magazine issue 60 - Delphi And Email 
var 
    MAPIError: DWord; 
    MapiMessage: TMapiMessage; 
    Originator, Recipient: TMapiRecipDesc; 
    Files, FilesTmp: PMapiFileDesc; 
    FilesCount: Integer; 
begin 
    FillChar(MapiMessage, Sizeof(TMapiMessage), 0); 

    MapiMessage.lpszSubject := PAnsiChar(AnsiString(Subject)); 
    MapiMessage.lpszNoteText := PAnsiChar(AnsiString(MessageText)); 

    FillChar(Originator, Sizeof(TMapiRecipDesc), 0); 

    Originator.lpszName := PAnsiChar(AnsiString(MailFromName)); 
    Originator.lpszAddress := PAnsiChar(AnsiString(MailFromAddress)); 
// MapiMessage.lpOriginator := @Originator; 
    MapiMessage.lpOriginator := nil; 


    MapiMessage.nRecipCount := 1; 
    FillChar(Recipient, Sizeof(TMapiRecipDesc), 0); 
    Recipient.ulRecipClass := MAPI_TO; 
    Recipient.lpszName := PAnsiChar(AnsiString(MailToName)); 
    Recipient.lpszAddress := PAnsiChar(AnsiString(MailToAddress)); 
    MapiMessage.lpRecips := @Recipient; 

    MapiMessage.nFileCount := High(AttachmentFileNames) - Low(AttachmentFileNames) + 1; 
    Files := AllocMem(SizeOf(TMapiFileDesc) * MapiMessage.nFileCount); 
    MapiMessage.lpFiles := Files; 
    FilesTmp := Files; 
    for FilesCount := Low(AttachmentFileNames) to High(AttachmentFileNames) do 
    begin 
    FilesTmp.nPosition := $FFFFFFFF; 
    FilesTmp.lpszPathName := PAnsiChar(AnsiString(AttachmentFileNames[FilesCount])); 
    Inc(FilesTmp) 
    end; 

    try 
    MAPIError := MapiSendMail(
     0, 
     Application.MainForm.Handle, 
     MapiMessage, 
     MAPI_LOGON_UI {or MAPI_NEW_SESSION}, 
     0); 
    finally 
    FreeMem(Files) 
    end; 

    case MAPIError of 
    MAPI_E_AMBIGUOUS_RECIPIENT: 
     Showmessage('A recipient matched more than one of the recipient descriptor structures and MAPI_DIALOG was not set. No message was sent.'); 
    MAPI_E_ATTACHMENT_NOT_FOUND: 
     Showmessage('The specified attachment was not found; no message was sent.'); 
    MAPI_E_ATTACHMENT_OPEN_FAILURE: 
     Showmessage('The specified attachment could not be opened; no message was sent.'); 
    MAPI_E_BAD_RECIPTYPE: 
     Showmessage('The type of a recipient was not MAPI_TO, MAPI_CC, or MAPI_BCC. No message was sent.'); 
    MAPI_E_FAILURE: 
     Showmessage('One or more unspecified errors occurred; no message was sent.'); 
    MAPI_E_INSUFFICIENT_MEMORY: 
     Showmessage('There was insufficient memory to proceed. No message was sent.'); 
    MAPI_E_LOGIN_FAILURE: 
     Showmessage('There was no default logon, and the user failed to log on successfully when the logon dialog box was displayed. No message was sent.'); 
    MAPI_E_TEXT_TOO_LARGE: 
     Showmessage('The text in the message was too large to sent; the message was not sent.'); 
    MAPI_E_TOO_MANY_FILES: 
     Showmessage('There were too many file attachments; no message was sent.'); 
    MAPI_E_TOO_MANY_RECIPIENTS: 
     Showmessage('There were too many recipients; no message was sent.'); 
    MAPI_E_UNKNOWN_RECIPIENT: 
     Showmessage('A recipient did not appear in the address list; no message was sent.'); 
    MAPI_E_USER_ABORT: 
     Showmessage('The user canceled the process; no message was sent.'); 
    SUCCESS_SUCCESS: 
     Showmessage('MAPISendMail successfully sent the message.'); 
    else 
    Showmessage('MAPISendMail failed with an unknown error code.'); 
    end; 
end; 




end. 

Answer 5

을 어쩌면이 이메일 창

System("mailto:someone@example.com?Subject=Hello%20again&body=your%20textBody%20here")