다른 오브젝트에 파워 포인트 라인을 분할

Question

파워 포인트 슬라이드가 많으며 각 슬라이드에는 많은 라인이 있지만 모든 라인은 동일한 오브젝트에 있습니다. 이제는 클릭 한 번으로 각 줄마다 나타나는 애니메이션을 추가하고 싶습니다.

나는 모든 라인이

주, 나는 파워 포인트 2010

감사합니다,

AA

Answer 1

이 사용하고 자신의 목적에있을 것 있도록 각 슬라이드에 라인을 분할 할 수있는 방법 완벽하지 않습니다. 원본 텍스트에서 모든 서식을 선택하기 위해 더 많은 코드를 추가해야하지만 시작일뿐입니다. 수정할 텍스트 상자를 클릭 한 다음 TEST 하위를 실행하십시오. 취향에 맞게 조정 한 후에는 전체 프레젠테이션의 모든 텍스트 상자에 적용되도록 테이블을 확장하는 것이 매우 간단합니다 (테이블, 차트, 스마트 아트 등은 아님)

Sub Test() 
    TextBoxToLines ActiveWindow.Selection.ShapeRange(1) 
End Sub 


Sub TextBoxToLines(oSh As Shape) 

    Dim oSl As Slide 
    Dim oNewShape As Shape 
    Dim oRng As TextRange 
    Dim x As Long 

    With oSh 
    Set oSl = .Parent 
    With .TextFrame.TextRange 
     For x = 1 To .Paragraphs.Count 
      Set oRng = .Paragraphs(x) 
      Set oNewShape = oSl.Shapes.AddTextbox(msoTextOrientationHorizontal, _ 
       oRng.BoundLeft, oRng.BoundTop, oRng.BoundWidth, oRng.BoundHeight) 
      With oNewShape 
       .TextFrame.AutoSize = ppAutoSizeNone 
       .Left = oRng.BoundLeft 
       .Top = oRng.BoundTop 
       .Width = oSh.Width 
       .Height = oSh.Height 
       With .TextFrame.TextRange 
        .Text = oRng.Text 
        .Font.Name = oRng.Font.Name 
        .Font.Size = oRng.Font.Size 
        ' etc ... pick up any other font formatting you need 
        ' from oRng, which represents the current paragraph of 
        ' the original text 
        ' Bullets, tabs, etc. 
       End With 
      End With 
     Next 
    End With 
    End With 

    oSh.Delete 

End Sub