간단한 스크립트를 actionscript2에서 actionscript3으로 변환

Question

저는 as3의 초보자이며 간단한 플래시 스케치 스크립트를 따라갔습니다. 다음은 링크 입니다. as2로 코딩되었지만 코드를 as3으로 변환하려고합니다. 코드를 as3으로 변환하려고 시도했지만 제대로 작동하지 않는 것 같습니다. 나는 누군가가 저를 도울 수있는 것을 깊이 감사 할 것입니다.

createEmptyMovieClip("Line",1); 
Line.lineStyle(3,0x000000,300); 

onMouseDown = function() { 
    Line.moveTo(_xmouse, _ymouse); 
    onMouseMove = function() { 
     Line.lineTo(_xmouse, _ymouse); 
    } 
} 

onMouseUp=function() { 
    onMouseMove=null; 
} 

Answer 1

이 AS3에서 줄 것이다 : 나는 당신이 어떻게 작동하는지 이해할 수 있도록, 전체 작업 예제를 만들하기로 결정

var Line:Sprite = new Sprite(); 
addChild(Line); 
Line.graphics.lineStyle(3, 0x000000, 1); 

stage.addEventListener(MouseEvent.MOUSE_DOWN, mouseDownHandler); 
addEventListener(MouseEvent.MOUSE_UP, mouseUpHandler); 

function mouseDownHandler(e:MouseEvent):void { 
    Line.graphics.moveTo(e.stageX, e.stageY); 
    stage.addEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler); 
} 

function mouseMoveHandler(e:MouseEvent):void { 
    Line.graphics.lineTo(e.stageX, e.stageY); 
} 

function mouseUpHandler(e:MouseEvent):void { 
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, mouseMoveHandler); 
} 

Answer 2

;

package { 
    import flash.display.Shape; 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 

    /** 
    * ... 
    * @author Martyn 
    */ 
    public class Main extends Sprite { 

     public var draw:Shape = new Shape(); 

     public function Main():void { 
      if (stage) init(); 
      else addEventListener(Event.ADDED_TO_STAGE, init); 
     } 

     private function init(e:Event = null):void { 
      removeEventListener(Event.ADDED_TO_STAGE, init); 
      stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); 
      stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp); 

      trace("init"); 
      addChild(draw); 
      draw.graphics.lineStyle(3, 0x000000, 300); 

     } 
     private function onMouseDown(e:MouseEvent):void 
     { 
      stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
      draw.graphics.moveTo(mouseX, mouseY); 
      trace("onMouseDown"); 
     } 

     private function onMouseUp(e:MouseEvent):void 
     { 
      stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
      trace("onMouseUp"); 
     } 

     private function onMouseMove(e:MouseEvent):void 
     { 
      draw.graphics.lineTo(mouseX, mouseY); 
      trace("onMouseMove"); 
     } 

    } 

} 

이 기능이 도움이되기를 바랍니다.