값이 양식의 텍스트 상자 값과 일치하면 시트에서 행을 삭제 하시겠습니까?

Question

좋아요, 그래서 Excel에서 userform을 가지고 있고, 폼에 "IMEITextBox"라는 텍스트 박스가 있습니다. Coloum B에 IMEI 번호가있는 재고 목록이 있습니다. IMEITextBox에 IMEI 번호를 입력 할 때 저장할 때 "Inventory"시트에서 해당 IMEI 번호를 포함하는 행을 삭제하려고합니다. 나는 이것을 며칠 동안 계속 연구했다. 캔트는 저에게 효과가있는 것을 찾는 것 같습니다. 도와 주실 수 있습니까? 코드를보고 난 후에 그것을 ... 이해에 문제가되지 않도록

Sub DeleteRows(IMEI) 

Dim ws As Worksheet 
Dim lastRow As Long, i As Long 
Dim strSearch As String 
Dim aCell As Range 

On Error GoTo Err 
Set ws = Sheets("Inventory") 
lastRow = ws.Range("IMEIRange" & Rows.Count).End(xlUp).Row 
strSearch = IMEITextBox.Value 
Set aCell = ws.Range("IMEIRange" & lastRow).Find(What:=strSearch, LookIn:=xlValues, _ 
LookAt:=xlPart, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
MatchCase:=False, SearchFormat:=False) 
If Not aCell Is Nothing Then 
    ws.Rows(lastRow).Delete 
End If 
Exit Sub 
Err: 
MsgBox Err.Description 

End Sub 

Answer 1

내가 코드를 댓글을 달았, 당신은 당신이 매우 가까웠다 것을 알게 될 것이다)

Option Explicit 

Sub DeleteRows() 
    Dim ws As Worksheet 
    Dim strSearch As String 
    Dim aCell As Range 

    On Error GoTo Err 

    '~~> Set the sheet where you want to search the IMEI 
    Set ws = Sheets("Inventory") 

    With ws 
     '~~> Get the value which you want to search 
     strSearch = IMEITextBox.Value 

     '~~> Column A is Column 1 so Column B is 2. This is where we are searching 
     '~~> xlWhole is used in the code below so that we find a complete match 
     '~~> xlPart is supposed to be used when you are finding a partial match. 
     Set aCell = .Columns(2).Find(What:=strSearch, LookIn:=xlValues, _ 
     LookAt:=xlWhole, SearchOrder:=xlByRows, SearchDirection:=xlNext, _ 
     MatchCase:=False, SearchFormat:=False) 

     '~~> Check if we found the value 
     If Not aCell Is Nothing Then 
      '~~> get the row of the cell where we found the match and delete it 
      .Rows(aCell.Row).Delete 
     Else '<~~ If not found 
      MsgBox "IMEI Number not Found" 
     End If 
    End With 

    Exit Sub 
Err: 
    MsgBox Err.Description 
End Sub