세마포어를 사용하는 응용 프로그램의 인스턴스를 세 개만 허용하십시오.

Question

세마포어를 사용하여 간단한 루틴을 구현하려고합니다. 세마포어를 사용하면 응용 프로그램의 인스턴스를 세 개만 실행할 수 있습니다. 나는 3 개의 뮤텍스를 사용할 수 있지만 좋은 접근법이 아니다. 지금까지 시도해 본 것이다.

var 
    hSem:THandle; 
begin 
    hSem := CreateSemaphore(nil,3,3,'MySemp3'); 
    if hSem = 0 then 
    begin 
    ShowMessage('Application can be run only 3 times at once'); 
    Halt(1); 
    end; 

어떻게하면 제대로 할 수 있습니까?

Answer 1

응용 프로그램이 종료 될 때 자동으로 수행되지 않으므로 항상 세마포를 해제해야합니다.

program Project72; 

{$APPTYPE CONSOLE} 

uses 
    Windows, 
    SysUtils; 

var 
    hSem: THandle; 

begin 
    try 
    hSem := CreateSemaphore(nil, 3, 3, 'C15F8F92-2620-4F3C-B8EA-A27285F870DC/myApp'); 
    Win32Check(hSem <> 0); 
    try 
     if WaitForSingleObject(hSem, 0) <> WAIT_OBJECT_0 then 
     Writeln('Cannot execute, 3 instances already running') 
     else begin 
     try 
      // place your code here 
      Writeln('Running, press Enter to stop ...'); 
      Readln; 
     finally ReleaseSemaphore(hSem, 1, nil); end; 
     end; 
    finally CloseHandle(hSem); end; 
    except 
    on E: Exception do 
     Writeln(E.ClassName, ': ', E.Message); 
    end; 
end. 

Answer 2

JCL에서 TJclAppInstances을 사용할 수 있습니다.

Answer 3

1. 당신은 당신이 잠금을 해제해야합니다, 그것은 당신이 카운트 끝에
2. 를 얻을 수 있는지 확인하기 위해 대기 기능 중 하나를 사용해야합니다
3. 를 생성 있는지 확인하기 위해 시도해야 & 이

건배를 다음 번에 사용자 가까이 작동하고 응용 프로그램을 열 수 있도록 처리

var 
    hSem: THandle; 
begin 
    hSem := OpenSemaphore(nil, SEMAPHORE_ALL_ACCESS, True, 'MySemp3'); 
    if hSem = 0 then 
    hSem := CreateSemaphore(nil, 3, 3,'MySemp3'); 

    if hSem = 0 then 
    begin 
    ShowMessage('... show the error'); 
    Halt(1); 
    Exit;  
    end; 

    if WaitForSingleObject(hSem, 0) <> WAIT_OBJECT_0 then 
    begin 
    CloseHandle(hSem); 
    ShowMessage('Application can be runed only 3 times at once'); 
    Halt(1); 
    Exit; 
    end; 

    try 
    your application.run codes.. 

    finally 
    ReleaseSemaphore(hSem, 1, nil); 
    CloseHandle(hSem); 
    end;