KRL에서 산책로를 검사하고 상호 작용하는 방법은 무엇입니까?

Question

KRL에서 앱 기록을 추적하는 데 사용하는 흔적이 있습니다. 트레일을 디버그하는 쉬운 방법을 찾고 있는데, 현재 트레일에있는 것을보고 지우는 것을 포함합니다.

KRL에서 쉽게 할 수 있습니까?

Answer 1

내게 가장 쉬운 방법은 브라우저 콘솔에 내용을 출력하는 것입니다.

rule inspect_data_on_trail { 
    select when pageview ".*" 
    pre { 
    visitedDomains = ent:visitedDomains; 
    } 
    { 
    emit <| 
     console.log(visitedDomains); 
    |>; 
    } 
} 

불을 지르고 출력 룰을 여러 번 실행 한 후 : 산책로를 포함하는 개체 변수를 지우려면

을, 나는 보통 내 응용 프로그램의의 일부가 아닌 도메인에 선택하는 규칙을 작성할 앱이 해당 도메인에서 실행될 때 varaibles를 경험하고 경험치를 지우십시오.

rule clear_everything { 
    select when pageview "yahoo\.com" 
    { 
    notify("Cleared",":)") with sticky = true; 
    } 
    fired { 
    clear ent:visitedDomains; 
    } 
} 

전체 예제 응용 프로그램 :

ruleset a60x458 { 
    meta { 
    name "trail-debugging" 
    description << 
     trail-debugging 
    >> 
    author "Mike Grace" 
    logging on 
    } 

    rule put_data_onto_trail { 
    select when pageview ".*" 
    pre { 
     domain = page:url("domain"); 
    } 
    { 
     notify("Thanks for visiting #{domain}","You visit has been recorded") with sticky = true; 
    } 
    fired { 
     mark ent:visitedDomains with domain; 
    } 
    } 

    rule inspect_data_on_trail { 
    select when pageview ".*" 
    pre { 
     visitedDomains = ent:visitedDomains; 
    } 
    { 
     emit <| 
     console.log(visitedDomains); 
     |>; 
    } 
    } 

    rule clear_everything { 
    select when pageview "yahoo\.com" 
    { 
     notify("Cleared",":)") with sticky = true; 
    } 
    fired { 
     clear ent:visitedDomains; 
    } 
    } 

}