붙여 넣기 단추가있는 새로운 워크 시트 열기

Question

사용자가 단추를 클릭하고 붙여 넣기 단추로만 작동하는 다른 매크로 단추가있는 새 워크 시트를 채우는 매크로 작업을하는 중입니다. 사용자는 그들이 무엇을 복사했는지. 현재 사용자는 "스크린 샷 추가"라는 버튼을 클릭하고 스크린 샷 워크 시트의 이름을 묻는 입력 상자가 표시됩니다. 사용자는 제목을 쓰고 사용자의 입력 제목으로 워크 시트의 이름으로 새 탭이 형성됩니다.

Sub AddScreenShot() 

Dim Title As Variant 


Title = Application.InputBox("Enter a Title: ", "Add Screen Shot", , 400, 290, , , Type:=2) 

    If Title = False Then 
     Exit Sub 

    ElseIf Title = vbNullString Then 
     MsgBox "A title was not entered. Please enter a Title" 
     Exit Sub 

    ElseIf Len(Title) > 15 Then 
     MsgBox "No more than 15 characters please" 
     Run "AddScreenShot" 

    Else 

    ActiveWorkbook.Worksheets.Add(After:=Worksheets(Worksheets.Count)).name = Title 

    End If 


End Sub 

이미 열려 시트 내에서 활성 셀에 클립 보드의 이미지를 붙여 넣 서브 루틴이 있습니다 : 여기에 그렇게 할 수있는 코드

Sub Paste_Image() 

On Error GoTo PasteError 

    Application.ScreenUpdating = False 
    Range("E5").Activate 
    ActiveSheet.Paste 
    Application.ScreenUpdating = True 
    ActiveSheet.Unprotect Password:=xxxx 

GetOutOfHere: 
    Exit Sub 

PasteError: 
    MsgBox "Please verify that an image has been copied", vbInformation, "Paste Image" 
    Resume GetOutOfHere 

End Sub 

문제는 나도 몰라하는 방법에 사용자가 시트의 제목을 입력하고 확인을 클릭하면 새 시트가 위의 붙여 넣기 서브 루틴을 실행할 매크로 버튼으로 채워지도록 두 코드 스 니펫을 함께 연결합니다. 두 링크를 연결하고 사용자가 확인을 클릭하여 새 워크 시트를 만들 때 붙여 넣기 하위를 실행하는 것에 대한 제안 사항은 무엇입니까?

감사합니다.

Answer 1

런타임에 버튼을 만들 수 있습니다.

이 메서드를 사용하면 시트를 만들 때 프로그래밍 방식으로 단추를 추가 할 수 있습니다. . 당신이 할 수있는 이름 = Title` 라인 :은`ActiveWorkbook.Worksheets.Add (= 워크 시트 (Worksheets.Count) 후) 후

Sub AddScreenShot() 

    Dim Title As Variant 
    Dim btn As Button 
    Dim t As Range 
    Dim sht As Worksheet 

    Title = Application.InputBox("Enter a Title: ", "Add Screen Shot", , 400, 290, , , Type:=2) 

     If Title = False Then 
      Exit Sub 

     ElseIf Title = vbNullString Then 
      MsgBox "A title was not entered. Please enter a Title" 
      Exit Sub 

     ElseIf Len(Title) > 15 Then 
      MsgBox "No more than 15 characters please" 
      Run "AddScreenShot" 

     Else 

      On Error Resume Next 
      Set sht = ActiveWorkbook.Worksheets(Title) 
      On Error GoTo 0 

      If Not sht Is Nothing Then 
       MsgBox "A worksheet named " & Title & " already exists!" 
       Run "AddScreenShot" 

      Else 

       Application.ScreenUpdating = False 
       ActiveWorkbook.Worksheets.Add(After:=Worksheets(Worksheets.Count)).Name = Title 
       Set t = ActiveSheet.Range("A1:B2") 'Button will appear in cell A1:B2, change to whatever you want. 

       Set btn = ActiveSheet.Buttons.Add(t.Left, t.Top, t.Width, t.Height) 'This will make the button the size of the cell, may want to adjust 
       With btn 
        .OnAction = "Paste_Image" 'Calls the Paste_Image subroutine when clicked 
        .Caption = "Paste" 'Change caption as you see fit 
        .Name = "btnPaste" 'Change name as you see fit 
       End With 

       Application.ScreenUpdating = True 
      End If 
     End If 


    End Sub