배치 또는 파일을 사용하여 현재 절대 경로를 검색하여 파일 또는 디렉토리를 찾으십니까?

Question

현재 디렉터리 경로를 검색하고 해당 경로에 인접한 특정 파일이나 디렉터리를 찾으려고합니다. 예 : 스크립트의 현재 디렉토리가 C : \ Temp \ Dir1 \ Dir2 \ Dir3 \ Dir4 \ Dir5 \ Dir6 \ Test.bat이고 "jars"가 C : \ Temp \ jars을 찾은 다음 위쪽으로 검색하여 "jars"가있는 디렉토리를 찾으십시오.

이것은 구현 한 방법이지만 더 쉽고 간단한 방법이 있는지 궁금합니다.

@echo off 
SET TITLE=%~nx0 
SET SEARCHFOR=jars\Site.jar 
SET MYDIR=%~p0 
SET MYDRIVE=%~d0 
SET DIRCHAIN=%MYDIR:\= % 
:: searches first 4 levels of depth but can be increased if necessary 
ECHO Searching in directory chain: %MYDRIVE% %DIRCHAIN% 
FOR /F "tokens=1-4 delims= " %%G IN ("%DIRCHAIN%") DO (
    if exist %MYDRIVE%\%SEARCHFOR% (
    SET APPHOME=%MYDRIVE% 
    GOTO APPHOMESET 
) 
    if exist %MYDRIVE%\%%G\%SEARCHFOR% (
    SET APPHOME=%MYDRIVE%\%%G 
    GOTO APPHOMESET 
) 
    if exist %MYDRIVE%\%%G\%%H\%SEARCHFOR% (
    SET APPHOME=%MYDRIVE%\%%G\%%H\ 
    GOTO APPHOMESET 
) 
    if exist %MYDRIVE%\%%G\%%H\%%I\%SEARCHFOR% (
    SET APPHOME=%MYDRIVE%\%%G\%%H\%%I 
    GOTO APPHOMESET 
) 
    if exist %MYDRIVE%\%%G\%%H\%%I\%%J\%SEARCHFOR% (
    SET APPHOME=%MYDRIVE%\%%G\%%H\%%I\%%J 
    GOTO APPHOMESET 
) 
    GOTO FAILED 
) 
:FAILED 
ECHO Did not discover location of APPHOME containing %SEARCHFOR% 
ECHO Searched no deeper than %MYDRIVE%\%%G\%%H\%%I\%%J 
:APPHOMESET 
SET JREHOME=%APPHOME%\Javasoft\jre 
echo APPHOME is %APPHOME% 
echo JREHOME is %JREHOME% 
pause 

Answer 1

다음과 같이 아이디어는 대략 다음과 같습니다

1. 는 현재 작업 디렉토리와 배치 스크립트의 경로를 가져옵니다.

2. 하위 디렉토리 이름을 연결하십시오.

3. 결과 경로가 있으면 경로를 반환하고 종료하십시오.

4. 현재 작업 디렉토리가 본질적으로 루트 디렉토리 인 경우 Not found을 반환하고 종료하십시오.

5. 현재 작업 디렉토리의 상위 디렉토리를 가져 와서 2 단계부터 반복하십시오.

여기 간다 :

@ECHO OFF 

SET "subdir=%~1" 
SET "dir=%~f0" 

:loop 
    CALL :getdir "%dir%" 

    IF EXIST "%dir%\%subdir%\" (
    ECHO %dir%\%subdir% 
    GOTO :EOF 
) 

    IF "%dir:~-1%" == ":" (
    ECHO Directory "%subdir%" not found. 
    GOTO :EOF 
) 
GOTO loop 

:getdir 
SET "dir=%~dp1" 
SET "dir=%dir:~0,-1%"