Actionscript를 사용하여 웹캠을 사용하여 사진 캡처

Question

웹캠과 이미지가있는 간단한 액션 스크립트 파일이 있습니다. 내가 원하는 것은 버튼을 클릭하면 웹캠과 이미지의 순간을 캡처하여 브라우저의 DIV로 렌더링하려고합니다. 어떻게 캡처합니까? 나는 bitmapdata가 사용될 필요가 있다고 짐작하고있다. 코드를 통해이 작업을 수행하고 싶습니다.

Answer 1

는 여기에 내가이 질문에 대답하기 위해 자신을 쓴거야. Chrome, FF 및 IE9에서 테스트되었습니다.

Base64 인코더 (1 개는 here)와 png/jpg 인코더 (예 : Flex 라이브러리)가 필요합니다. 코드 AS

:

package 
{ 
    import flash.display.BitmapData; 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 
    import flash.external.ExternalInterface; 
    import flash.media.Camera; 
    import flash.media.Video; 

    [SWF(width="640", height="480", backgroundColor="#000000")] 
    public class CameraToJS extends Sprite 
    { 
     private var camera:Camera; 
     private var video:Video; 

     public function CameraToJS() 
     { 
      addEventListener(Event.ADDED_TO_STAGE, addedToStageHandler); 
      stage.addEventListener(MouseEvent.CLICK, saveSnapshot); 
     } 

     protected function addedToStageHandler(event:Event):void 
     { 
      camera = Camera.getCamera(); 
      video = new Video(); 
      video.attachCamera(camera); 
      addChild(video); 
     } 

     protected function saveSnapshot(event:MouseEvent):void 
     { 
      var bmData:BitmapData = new BitmapData(video.width, video.height); 
      bmData.draw(video); 

      var encoder:PNGEncoder = new PNGEncoder(); 

      ExternalInterface.call("image", Base64.encodeByteArray(encoder.encode(bmData))); 
     } 
    } 
} 

자바 스크립트 코드 :

function image(data) 
{ 
    document.getElementById("img").src = "data:image/png;base64,"+ data; 
} 

Answer 2

이 링크는 원하는 작업을 정확하게 수행 할 수 있도록 도와줍니다.

http://www.xarg.org/project/jquery-webcam-plugin/