모든 워크 시트를 순환하는 데 매크로가 필요합니다.

Question

다음 매크로가 있습니다. 활성 매크로가 아닌 통합 워크 시트의 모든 워크 시트에서 동일한 작업을 수행해야합니다. 나는 다양한 재료를 시험해 보았습니다. 그러나 나는 많은 경험이 없으므로 나는별로 운이 없어요.

다음은 매크로입니다. 통합 문서의 모든 시트를 반복 할

Sub Tester() 

Dim c As Range, rngMerge As Range 

For Each c In ActiveSheet.Range("A1").Resize(1, 100).Cells 
    Set rngMerge = c.MergeArea 
    If rngMerge.Cells.Count > 1 Then 
     c.UnMerge 
     rngMerge.Value = rngMerge.Cells(1).Value 
    End If 
    c.Value = JoinUp(c.Resize(3, 1), "_") 
Next c 
ActiveSheet.Range("A2:A3").EntireRow.Delete 
End Sub 


Function JoinUp(rng As Range, Optional Delim As String = "") As String 
Dim c As Range, rv As String 
For Each c In rng.Cells 
    If Len(c.Value) > 0 Then 
     rv = rv & IIf(Len(rv) > 0, Delim, "") & c.Value 
    End If 
Next c 
JoinUp = rv 
End Function 

Answer 1

, 당신은 사용할 수 있습니다

dim i as Integer 

    For i = 1 To ActiveWorkBook.WorkSheets.Count 
     ' do stuff 
     ActiveWorkbook.Worksheets(i) .... 
    Next i 

Answer 2

시도 :

Sheets(Array("Sheet2", "Sheet1")).Select 
Sheets("Sheet2").Activate 

또는 당신을 순환하려면 :

For Each aSheet In ActiveWorkbook.Sheets 
Next aSheet 

Answer 3

또는

을 사용하십시오.

dim sht as worksheet 

for each sht in thisworkbook.sheets 
     debug.print sht.name 
next sht 

Answer 4

Sub ProcessAll() 
    Dim sht as worksheet 
    for each sht in ActiveWorkbook.Worksheets 
     ProcessSheet sht 
    next sht 
End sub 


Sub ProcessSheet(sht as worksheet) 

Dim c As Range, rngMerge As Range 

For Each c In sht.Range("A1").Resize(1, 100).Cells 
    Set rngMerge = c.MergeArea 
    If rngMerge.Cells.Count > 1 Then 
     c.UnMerge 
     rngMerge.Value = rngMerge.Cells(1).Value 
    End If 
    c.Value = JoinUp(c.Resize(3, 1), "_") 
Next c 
sht.Range("A2:A3").EntireRow.Delete 
End Sub 


Function JoinUp(rng As Range, Optional Delim As String = "") As String 
    Dim c As Range, rv As String 
    For Each c In rng.Cells 
    If Len(c.Value) > 0 Then 
     rv = rv & IIf(Len(rv) > 0, Delim, "") & c.Value 
    End If 
    Next c 
    JoinUp = rv 
End Function