델파이 형식으로 파일 드래그 앤 드롭

Question

파일 탐색기에서 드래그 앤 드롭 된 파일을 수락하려고했지만 작동하지 않습니다. 내 WM_DROPFILES 처리기가 호출되지 않습니다. Windows 8을 실행 중이므로 차이가 있습니다.

여기 (난 그냥 폼에 잇는 TMemo이) 내가하는 일의 간단한 예입니다 :

type 
    TForm1 = class(TForm) 
    Memo1: TMemo; 
    private 
    { Private declarations } 
    procedure WMDROPFILES(var msg : TWMDropFiles) ; message WM_DROPFILES; 
    procedure CreateWnd; override; 
    procedure DestroyWnd; override; 
    public 
    { Public declarations } 
    end; 

var 
    Form1: TForm1; 

implementation 

{$R *.dfm} 

{ TForm1 } 

procedure TForm1.CreateWnd; 
begin 
    inherited; 
    DragAcceptFiles(Handle, True); 

end; 

procedure TForm1.DestroyWnd; 
begin 
    inherited; 
    DragAcceptFiles(Handle, false); 

end; 

procedure TForm1.WMDROPFILES(var msg: TWMDropFiles); 
var 
    i, fileCount: integer; 
    fileName: array[0..MAX_PATH] of char; 
begin 
    fileCount:=DragQueryFile(msg.Drop, $FFFFFFFF, fileName, MAX_PATH); 
    for i := 0 to fileCount - 1 do 
    begin 
    DragQueryFile(msg.Drop, i, fileName, MAX_PATH); 
    Memo1.Lines.Add(fileName); 
    end; 
    DragFinish(msg.Drop); 
end; 

Answer 1

당신이 당신의 응용 프로그램이 높은 실행 가능성이 높습니다. 아마도 델파이가 상승했기 때문일 것입니다. Vista 이상에서는 권한이 낮은 프로세스가 메시지를 상위 권한 프로세스에 보낼 수 없습니다. 이 MSDN blog에 대해 자세히 설명합니다.

Delphi IDE를 실행중인 경우, 그렇게하지 않는 것이 좋습니다. 표준 데스크톱 응용 프로그램 개발을 위해서는 그렇게 할 필요가 거의 없습니다. 레미가 지적 하듯이

---

, 당신의 DestroyWnd이 올바르지 않습니다. DragAcceptFiles을 호출하기 전에 창 핸들을 파괴하고 있습니다. 순서를 바꾸면됩니다. 개인적으로는 을 CreateWnd과 DestroyWnd에 모두 사용하고 싶습니다. Handle 속성은 할당되지 않았 으면 창 핸들을 만들어서 그러한 오류를 숨 깁니다.

procedure TForm1.CreateWnd; 
begin 
    inherited; 
    DragAcceptFiles(WindowHandle, True); 
end; 

procedure TForm1.DestroyWnd; 
begin 
    DragAcceptFiles(WindowHandle, false); 
    inherited; 
end;