xslt 및 xsltproc을 사용하여 xml에 파트를 추가하는 방법은 무엇입니까?

Question

나는 xml 파일이 있습니다

<?xml version="1.0" encoding="iso-8859-1"?> 
<Configuration> 
    <Parameter2> 
    </Parameter2> 
</Configuration> 

을 나는 <Configuration>과 <Parameter2> 부분 사이의 내 xml 파일에 대한 부분에 다음을 추가하고 싶습니다.

<Parameter1> 
    <send>0</send> 
    <interval>0</interval> 
    <speed>200</speed> 
</Parameter1> 

Answer 1

짧은 솔루션. 이 스타일 :

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:template match="@*|node()" name="identity"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()" /> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="Configuration/*[1]"> 
     <Parameter1> 
      <send>0</send> 
      <interval>0</interval> 
      <speed>200</speed> 
     </Parameter1> 
     <xsl:call-template name="identity" /> 
    </xsl:template> 
</xsl:stylesheet> 

출력 :

<Configuration> 
    <Parameter1> 
     <send>0</send> 
     <interval>0</interval> 
     <speed>200</speed> 
    </Parameter1> 
    <Parameter2></Parameter2> 
</Configuration> 

주 : Configuration/*[1][not(/Configuration/Parameter1)] : 어떤 위치에서 이러한 요소가 이미없는 경우에만이 Parameter1을 추가 할 경우의 패턴을 변경해야합니다

Answer 2

이 XSLT는 Parameter2 전에 Configuration 요소의 자식으로 지정된 내용을 삽입합니다.

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"> 
    <xsl:output indent="yes" /> 

    <xsl:template match="Configuration"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*" /> 
      <!--Check for the presence of Parameter1 in the config file to ensure that it does not get re-inserted if this XSLT is executed against the output--> 
      <xsl:if test="not(Parameter1)"> 
       <Parameter1> 
        <send>0</send> 
        <interval>0</interval> 
        <speed>200</speed> 
       </Parameter1> 
      </xsl:if> 
      <!--apply templates to children, which will copy forward Parameter2 (and Parameter1, if it already exists)--> 
      <xsl:apply-templates select="node()" /> 
     </xsl:copy> 
    </xsl:template> 

    <!--standard identity template, which copies all content forward--> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()" /> 
     </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet>