VBA 매크로

Question

내가 (HTML 형식으로) 내가 현재 쓰고있는 전자 메일 메시지에서 선택한 텍스트를 취할 것입니다 전망 2013에 대한 VBA 매크로를 만들려고하고 있고 설정 글꼴 크기/색상/굵게/강조 표시

내 매크로 두/다음의 경우 블록이있다. 하나의 블록은 Outlook 2003 용이며 4 가지 텍스트 특성 모두에 대해 원하는 결과를 제공합니다. 그러나 2003 년 이후 Outlook에서는 HTML 전자 메일 용 Word EditorType을 사용하므로 선택한 텍스트의 글꼴을 변경하는 데 다른 구문을 사용하여 다른 VBA 블록이 필요합니다. 내 2013 블록의 VBA는 굵게/포인트 크기를 변경하기 위해 올바르게 작동하지만 텍스트 강조 표시는 적용되지 않습니다. 대신 텍스트를 강조 표시하기위한 명령 (rng.Range.HighlightColorIndex = wdYellow)은 선택 창의 배경색을 지우도록 변경하므로 (텍스트가 실제로 선택되어 있어도 텍스트가 더 이상 선택되지 않게 표시됨) , 강조 표시는 선택한 텍스트에 적용되지 않습니다.

작동하지 않았다 텍스트를 강조

, 나는 다른 무언가를 시도했다. vba 명령을 사용하여 배경을 노란색으로 설정하려고했는데 (vba없이 수동으로 적용했을 때와 동일한 시각 효과가 있음) rng.Shading.BackgroundPatternColor = wdColorYellow. 그러나 배경을 노란색으로 바꾸는 대신 배경이 검은 색으로 바뀝니다.

또한 2,013 블록 폰트 색상 변화가 발생하지 않는다. 성명 (rng.Font.Color = wdColorBlue)에도 불구하고 글꼴 색이 검은 색으로 유지됩니다.

선택한 텍스트를 노란색으로 강조 표시하고 선택한 텍스트의 색을 파란색으로 설정하는 방법을 알려주십시오.

전체 VBA 매크로는 아래와 같습니다.

Sub ChangeSelectedFontBold14HiYellow() 
Dim msg As Outlook.MailItem 
Dim insp As Outlook.Inspector 

Set insp = Application.ActiveInspector 

If insp.CurrentItem.Class = olMail Then 
    Set msg = insp.CurrentItem 

    If insp.EditorType = olEditorHTML Then ' outlook 2003 
     Set hed = msg.GetInspector.HTMLEditor 
     Set rng = hed.Selection.createRange 
     rng.pasteHTML "<b><font style='color: blue; background: yellow; font-size: 14pt;'>" & rng.Text & "</font></b>" 
    End If 

    If insp.EditorType = olEditorWord Then ' outlook 2013 
     Set hed = msg.GetInspector.WordEditor 
     Set word = hed.Application 
     Set rng = word.Selection 
     rng.Font.Size = 14 
     rng.Font.Color = wdColorBlue ' color does not change 
     rng.Font.Bold = True 
     ' rng.Shading.BackgroundPatternColor = wdColorYellow ' changes background color to black instead of yellow 
     ' rng.HighlightColorIndex = wdYellow ' does not work ' error 438 object doesn't support this property 
     rng.Range.HighlightColorIndex = wdYellow ' does not work - changes the background to clear for the selection indicator color 

    End If 

End If 
Set insp = Nothing 
Set rng = Nothing 
Set hed = Nothing 
Set msg = Nothing 
End Sub 

Answer 1

당신은 Word 개체 라이브러리에 VBA 프로젝트 참조를 추가, 또는 그 정수를 Outlook이 wdColorBlue 및 wdYellow의 진정한 가치가 무엇인지 이해할 수 있도록 정의해야합니다. 나는 (당신이 참조를 추가하는 경우 그러나 당신은 변수 이름으로 Word을 사용할 수 없습니다)

다음

나 (더 많거나 적은 근무 무슨 코드가 원하는 효과를 가지고 있다고했다

- I이었다 직장에서 나는 Collapse 부분 Outlook에서 또한 Word에서 이렇게 해야 일을 잘 작동) ...하지만 거기 지금, 시험했을 때.

Sub ChangeSelectedFontBold14HiYellow() 
Dim msg As Outlook.MailItem 
Dim insp As Outlook.Inspector 

Set insp = Application.ActiveInspector 

If insp.CurrentItem.Class = olMail Then 
    Set msg = insp.CurrentItem 

    If insp.EditorType = olEditorHTML Then ' outlook 2003 
     Set hed = msg.GetInspector.HTMLEditor 
     Set rng = hed.Selection.createRange 
     rng.pasteHTML "<b><font style='color: blue; background: yellow; font-size: 14pt;'>" & rng.Text & "</font></b>" 
    End If 

    If insp.EditorType = olEditorWord Then ' outlook 2013 
     Set hed = msg.GetInspector.WordEditor 
     Set appWord = hed.Application 
     Set rng = appWord.Selection 
     rng.Font.Size = 14 
     rng.Font.Color = wdColorBlue 
     rng.Font.Bold = True 
     rng.Range.HighlightColorIndex = wdYellow 

     rng.Collapse Direction:=wdCollapseEnd 'UNTESTED, but something like this... 
    End If 

End If 

Set appWord = Nothing 
Set insp = Nothing 
Set rng = Nothing 
Set hed = Nothing 
Set msg = Nothing 

End Sub