EXCEL VBA : 열 및 복사 루핑

Question

있음 Excel에서 네 개의 열이 있습니다. 첫 번째 열에 숫자가 있고 두 번째 열은 비어 있고 세 번째 열은 숫자를 포함하고 네 번째 열은 텍스트를 포함합니다.

첫 번째 열의 각 값을 확인하고 세 번째 열에 있는지 확인하고 싶습니다. 일치하는 경우 해당하는 세 번째 열 옆에있는 네 번째 열의 값을 해당 첫 번째 열 옆의 두 번째 열에 복사해야합니다.

컴파일 오류가 발생합니다. 다음이없는 다음. 여기 내 코드는 지금까지 있습니다 :

Sub Compare() 

    Dim colA As Integer, colB As Integer 

    colA = Columns("A:A").Rows.Count 
    colB = Columns("C:C").Rows.Count 


     For I = 2 To colA 'loop through column A 

      For j = 2 To colB 'loop through column C 

       ' If a match is found: 
       If Worksheets("Sheet1").Cells(I, 1) = Workshee("Sheet1").Cells(j, 3) Then 
        ' Copy 
        Worksheets("Sheet1").Cells(j, 4) = Worksheets("Sheet1").Cells(I, 2) 
        'Exit For 

      Next j 

     Next I 

End Sub 

Answer 1

으로 이미 당신은 또한 VLookUp 또는 INDEX/MATCH의 조합으로이 작업을 수행 할 수 위의 댓글에서 지적했다. 그러나 VBA를 계속 사용하려면 코드를 약간 조정해야합니다. 둘 다 할 것입니다

Option Explicit 

Sub Compare() 

Dim ws As Worksheet 
Dim i As Long, j As Long 
Dim colA As Long, colC As Long 

Set ws = ThisWorkbook.Worksheets("Sheet1") 
colA = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row 
colC = ws.Cells(ws.Rows.Count, "C").End(xlUp).Row 

'loop through column A 
For i = 2 To colA 
    'loop through column C 
    For j = 2 To colC 
     ' If a match is found: 
     If ws.Cells(i, 1).Value2 = ws.Cells(j, 3).Value2 Then 
      ' Copy column B to Column D as written in your code above 
      ws.Cells(j, 4).Value2 = ws.Cells(i, 2).Value2 
      ' or copy column D to Column B as written in the question/post 
      ws.Cells(i, 2).Value2 = ws.Cells(j, 4).Value2 
      'Exit For 
     End If 
    Next j 
Next i 

ws.Range("D2:D" & colC).FormulaR1C1 = "=INDEX(R2C2:R" & colA & "C2,MATCH(RC[-1],R2C1:R" & colA & "C1,0))" 

End Sub 

위의 코드 :

1. VBA를 방법 및
2. 당신을위한 INDEX/MATCH 수식을 작성합니다.

원하지 않는 코드 세그먼트 만 삭제하면됩니다.

Answer 2

코드 사용을 주장하는 경우이 고정 버전을 사용하십시오. 그것은 테스트되지 않은 있지만 잘 작동합니다.

Sub Compare() 
Dim LastRowA As Long, LastRowB As Long, i As Long, j As Long 

With Worksheets("Sheet1") 
    LastRowA = .Range("A" & Rows.Count).End(xlUp).Row 
    LastRowC = .Range("C" & Rows.Count).End(xlUp).Row 

    For i = 2 To LastRowA 

     For j = 2 To LastRowC 

       If .Cells(i, 1) = .Cells(j, 3) Then .Cells(i, 2) = .Cells(j, 4): Exit For 

     Next j 

    Next i 

End With 

End Sub 

오류가 있으면 알려주세요.