@@ FETCH_STATUS가 커서 외부에 있습니다.

Question

XML 데이터를 처리하는 쿼리가 있으며 커서에서 반환 된 데이터에 대해 while(@@FETCH_STATUS = 0) 루프를 사용합니다.

Management Studio를 사용하여 쿼리를 실행하면 @@FETCH_STATUS은 -1이고 내 루프 안의 코드는 생략됩니다. 디버거를 사용하여 쿼리를 실행하고 계속 누르면 잘 실행되고 @@FETCH_STATUS은 0과 같습니다. 쿼리를 다시 실행하면 디버그에서 실행 한 후 @@FETCH_STATUS은 0이고 -1로 변경됩니다.

요약하면 :

1. 을 내가 SSMS 실행 - @@FETCH_STATUS = -1
2. 내가 디버거를 실행 - @@FETCH_STATUS = 0 (나는이 값을 원하는) 내가 SSMS 실행
3. 을 한 번 @@FETCH_STATUS 여전히 동일 디버거를 실행 한 후 0이지만 -1로 변경됩니다.

나는 OPEN cursor, 및 DEALLOCATE cursor을 사용합니다. 왜 이런 방식으로 작동합니까?

편집 :

IF (OBJECT_ID('dbo.XmlOrderResponses') IS NOT NULL) 
    DROP TABLE XmlOrderResponses; 

CREATE TABLE XmlOrderResponses (
    OrderResponseType INT 
    ,OrderResponseNumber NVARCHAR(40) 
    ,OrderResponseDate DATETIME 
    ,DocumentFunctionCode NVARCHAR(40) 
    ,Remarks INT 
    ); 

DECLARE CUR CURSOR 
FOR 
SELECT Subdirectory 
FROM XMLFiles; 

OPEN CUR 

WHILE (@@FETCH_STATUS = 0) 
BEGIN 
    DECLARE @DocHandle AS INT; 
    DECLARE @TMP AS NVARCHAR(512); 

    FETCH NEXT 
    FROM Cur 
    INTO @TMP 

    DECLARE @XmlDocument AS NVARCHAR(MAX); 

    SET @XmlDocument = (
      SELECT CAST(XMLSource AS NVARCHAR(max)) 
      FROM XMLFiles 
      WHERE subdirectory = @TMP 
      ); 

    EXEC sys.sp_xml_preparedocument @DocHandle OUTPUT 
     ,@XmlDocument; 

    INSERT INTO XmlOrderResponses (
     OrderResponseType 
     ,OrderResponseNumber 
     ,OrderResponseDate 
     ,DocumentFunctionCode 
     ,Remarks 
    ) 
SELECT * 
FROM OPENXML(@DocHandle, '/Document-OrderResponse/*', 11) WITH (
     OrderResponseType INT 
     ,OrderResponseNumber NVARCHAR(40) 
     ,OrderResponseDate DATETIME 
     ,DocumentFunctionCode NVARCHAR(40) 
     ,Remarks INT 
     ); 

    EXEC sys.sp_xml_removedocument @DocHandle; 
END 

CLOSE CUR; 

DEALLOCATE CUR; 

--I know I shouldn't be doing that but I can't get rid of NULL records the other way. 
DELETE 
FROM XmlOrderResponses 
WHERE OrderResponseType IS NULL 
    AND OrderResponseNumber IS NULL 
    AND OrderResponseDate IS NULL 
    AND DocumentFunctionCode IS NULL 
    AND Remarks IS NULL; 

SELECT * 
FROM XmlOrderResponses 

SELECT @@FETCH_STATUS 

Answer 1

문제는 당신이 @@FETCH_STATUS를 참조 처음으로, 당신은 당신의 커서를 가져 오기를 수행하지 않은, 그래서 마지막으로 사용한 커서를 참조된다는 점이다 : 코드는 당신을 위해 물었다. 이 간단한 예제 상상 : 당신은 폐쇄하고 (다른 FETCH이 이후에 수행되지 않았기 때문에) @@FETCH_STATUS는 여전히 커서를 참조하고, C1 해제에도 불구하고, 주석 줄에

DECLARE C1 CURSOR 
FOR 
    SELECT TOP 3 ID 
    FROM (VALUES ('1'), ('2'), ('3')) t (ID); 

OPEN C1; 

WHILE @@FETCH_STATUS = 0 
BEGIN 
    DECLARE @c1 CHAR(1); 
    FETCH NEXT FROM C1 INTO @c1; 
    PRINT @c1; 
END 

CLOSE C1; 
DEALLOCATE C1; 

DECLARE C2 CURSOR 
FOR 
    SELECT TOP 3 ID 
    FROM (VALUES ('1'), ('2'), ('3')) t (ID); 

OPEN C2; 

-- HERE @@FETCH_STATUS REFERS TO THE LAST FETCH FOR CURSOR `C1` NOT `C2` 
SELECT @@FETCH_STATUS; 

WHILE @@FETCH_STATUS = 0 
BEGIN 
    DECLARE @c2 CHAR(1); 
    FETCH NEXT FROM C2 INTO @c2; 
    PRINT @c2; 
END; 

CLOSE C2; 
DEALLOCATE C2; 

을, 그래서 당신은 입력 결코 당신의 loop for C2

루프 전에 가져 오기를 수행 한 다음 시작 부분보다는 각 루프의 끝에서 수행해야합니다.

DECLARE @TMP AS NVARCHAR(512); 
OPEN CUR 
-- DO FETCH FIRST 
FETCH NEXT FROM Cur INTO @TMP 

WHILE (@@FETCH_STATUS = 0) 
BEGIN 
    DECLARE @DocHandle AS INT; 

    -- DO ALL YOUR WORK WITH @TMP 


    --PERFORM THE FETCH AGAIN AT THE END OF THE LOOP 
    FETCH NEXT FROM Cur INTO @TMP 
END 

각 루프의 시작 FETCH 일을 함께 가지고 다른 문제는, 마지막 항목이 두 번 처리 할 것입니다. 다시 간단한 예 @@FETCH_STATUS 인 경우 -1, FETCH 단지에있는 항목을 반환합니다 때문에이

1 
1 

를 인쇄합니다

DECLARE C1 CURSOR 
FOR 
    SELECT ID = '1'; 

OPEN C1; 
DECLARE @c CHAR(1); 
WHILE (@@FETCH_STATUS = 0) 
BEGIN 
    DECLARE @c1 CHAR(1); 
    FETCH NEXT FROM C1 INTO @c1; 
    PRINT @c1; 
END 

(당신은 @@ FETCH_STATUS = 0 루프를 입력 가정) 현재 위치.