CMD 창을 열고 PING을 실행하는 BAT 파일

Question

매우 불안정한 인터넷 연결이 있습니다. 이 경우 CMD 창에서 ping 테스트를 실행해야합니다. 죄송합니다.이 시작> 실행> CMD를 입력하거나 ping www.XXXXX@com -t를 입력하면 너무 게으르다. , evrytime 브라우징을 시작해야합니다.

나는 A A CMD 창을 엽니 다 박쥐 파일을 자동으로 실행 ping 테스트가 필요 예 : www.yahoo, COM -t

Answer 1

이 당신이 필요로하는 것보다 조금 더 될 수도 있지만 그것은 아주 일반적이었다 전화 접속 일에 스크립트를 사용했습니다. 이 게시물을 오래된 포럼 게시물에서 찾아서 수정합니다. 당신이 로그인 할 때마다 체크 있도록

@ECHO off 

    ::============================================ 
    :: \\\\\\\\\\\\\\ Variables ////////////// 
    ::============================================ 
    SET drive=c:\nettest 
    SET OutputFile=result.txt 
    SET tt=%time:~0,2%_%time:~3,2%_result.txt 
    SET folder=%date:/=-% %tt% 
    SET site1=www.google.com 
    SET site2=www.yahoo.com 

    ::============================================ 
    :: \\\\\\\\\\\\\\ Message //////////////// 
    ::============================================ 

    COLOR 9F 
    ECHO. Ping all sites 
    PAUSE 

    GOTO Google 

    ::================================================== 
    :: \\\\\\\\\\\\\\ Pinging Google //////////////// 
    ::================================================== 
    :Google 
    PING -n 2 %site1% | find "Reply from" 

    ::Check to see if ping was successful or unsuccesful 
    ::successful = :found1 
    ::unsuccessful = :nfound1 
    IF NOT ERRORLEVEL 1 GOTO found1 
    IF ERRORLEVEL 1 GOTO nfound1 

    ::Check to see if folder exists 
    :found1 
    ECHO. 
    ECHO Google found! 
    ECHO. 
    IF EXIST "%drive%\%folder%" GOTO :write1 
    IF NOT EXIST "%drive%\%folder%\" GOTO :create1 

      ::Folder found - writes output 
      :write1 
      ECHO ping to google successful on Date (%date%), Time (%time%). >>"%drive%\%folder%\%tt%" 
      GOTO yahoo 

      ::Folder not found - creates folder and writes output 
      :create1 
      MD "%drive%\%folder%\" 

      ECHO ping to google successful on Date (%date%), Time (%time%). >>"%drive%\%folder%\%tt%" 
      GOTO yahoo 

    :nfound1 
    ECHO. 
    ECHO ###Google NOT FOUND! 
    ECHO. 
    IF EXIST "%drive%\%folder%" GOTO :write2 
    IF NOT EXIST "%drive%\%folder%\" GOTO :create2 

      :write2 
      ECHO ping to google unsuccessful on Date (%date%), Time (%time%). >>"%drive%\%folder%\%tt%" 
      GOTO yahoo 

      :create2 
      MD "%drive%\%folder%\" 

      ECHO ping to google unsuccessful on Date (%date%), Time (%time%). >>"%drive%\%folder%\%tt%" 
      GOTO yahoo 

    ::======================================================== 
    :: \\\\\\\\\\\\\\ Pinging Yahoo //////////////// 
    ::======================================================== 
    :yahoo 
    PING -n 2 %site2% | find "Reply from" 
    IF NOT ERRORLEVEL 1 GOTO found2 
    IF ERRORLEVEL 1 GOTO nfound2 

    :found2 
    ECHO. 
    ECHO Yahoo found! 
    ECHO ping to Yahoo successful on Date (%date%), Time (%time%). >>"%drive%\%folder%\%tt%" 
    GOTO Finished 

    :nfound2 
    ECHO. 
    ECHO ###Yahoo NOT FOUND! 
    ECHO ping to Yahoo unsuccessful on Date (%date%), Time (%time%). >>"%drive%\%folder%\%tt%" 
    GOTO Finished 


    ::========================================================== 
    :: \\\\\\\\\\\\\\ Test finished //////////////// 
    ::========================================================== 
    :Finished 
    ECHO. 
    ECHO Test Completed! 
    ECHO. 

    @PAUSE 

당신은 당신의 시작이 뭔가를 추가 할 수 있습니다.

• OP를위한 명확성. 이 파일을 복사하여 바탕 화면의 새로운 텍스트 파일에 붙여넣고 pingcheck.bat (.bat.txt가 아닌 .bat 만 확인하십시오.)이라고합니다. 그런 다음 두 번 클릭하여 실행하십시오. Windows 98, XP, 7에서 작동합니다 (테스트 할 Win8 상자가 없습니다).이 작업은 3.1, 95, 2000 및 ME에서도 가능합니다.