as3 품질 문제를 사용하는 ipad 비디오 디스플레이

Question

as3 코드를 사용하여 ipad에서 전면 카메라를 얻을 수 있었지만 비디오 화질이 매우 낮습니다. 아래 코드를 사용했습니다.

camera=Camera.getCamera(frontcamIndex); 
camera.setQuality (0,90); 
user1video.width = 320; 
user1video.height =240; 
user1video.attachCamera(camera); 

Answer 1

아래 코드에 대해 setMode 함수를 설정했습니다.

camera.setMode(320, 240, <#your value#>);

은 다음 문서를 참조하십시오.

http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/media/Camera.html#setMode()

그리고 난에서는 CameraUI를도록 권장한다. CameraUI 클래스를 사용하면 장치의 기본 카메라 응용 프로그램을 사용하여 스틸 이미지 또는 비디오를 캡처 할 수 있습니다.

http://help.adobe.com/en_US/FlashPlatform/reference/actionscript/3/flash/media/CameraUI.html

다음은 장치의 기본 카메라 응용 프로그램을 실행하기 위해에서는 CameraUI 클래스를 사용합니다. 사용자가 사진을 찍으면이 예제는 이미지를 표시 목록에 배치합니다.

package { 
import flash.desktop.NativeApplication; 
import flash.display.Loader; 
import flash.display.MovieClip; 
import flash.display.StageAlign; 
import flash.display.StageScaleMode; 
import flash.events.ErrorEvent; 
import flash.events.Event; 
import flash.events.IOErrorEvent; 
import flash.events.MediaEvent; 
import flash.media.CameraUI; 
import flash.media.MediaPromise; 
import flash.media.MediaType; 

    public class CameraUIStillImage extends MovieClip{ 

      private var deviceCameraApp:CameraUI = new CameraUI(); 
      private var imageLoader:Loader; 

      public function CameraUIStillImage() { 
       this.stage.align = StageAlign.TOP_LEFT; 
       this.stage.scaleMode = StageScaleMode.NO_SCALE; 

       if(CameraUI.isSupported) 
       { 
       trace("Initializing camera..."); 

       deviceCameraApp.addEventListener(MediaEvent.COMPLETE, imageCaptured); 
       deviceCameraApp.addEventListener(Event.CANCEL, captureCanceled); 
       deviceCameraApp.addEventListener(ErrorEvent.ERROR, cameraError); 
       deviceCameraApp.launch(MediaType.IMAGE); 
       } 
       else 
       { 
       trace("Camera interface is not supported."); 
       } 
      } 

      private function imageCaptured(event:MediaEvent):void 
      { 
       trace("Media captured..."); 

       var imagePromise:MediaPromise = event.data; 

       if(imagePromise.isAsync) 
       { 
       trace("Asynchronous media promise."); 
       imageLoader = new Loader(); 
       imageLoader.contentLoaderInfo.addEventListener(Event.COMPLETE, asyncImageLoaded); 
       imageLoader.addEventListener(IOErrorEvent.IO_ERROR, cameraError); 

       imageLoader.loadFilePromise(imagePromise); 
       } 
       else 
       { 
       trace("Synchronous media promise."); 
       imageLoader.loadFilePromise(imagePromise); 
       showMedia(imageLoader); 
       } 
      } 

      private function captureCanceled(event:Event):void 
      { 
       trace("Media capture canceled."); 
       NativeApplication.nativeApplication.exit(); 
      } 

      private function asyncImageLoaded(event:Event):void 
      { 
       trace("Media loaded in memory."); 
       showMedia(imageLoader);  
      } 

      private function showMedia(loader:Loader):void 
      { 
       this.addChild(loader); 
      } 

      private function cameraError(error:ErrorEvent):void 
      { 
       trace("Error:" + error.text); 
       NativeApplication.nativeApplication.exit(); 
      } 
    } 
}