클래스의 Perl 프로토 타입 서브 루틴

Question

객체를 인스턴스화하지 않고 클래스에서 프로토 타입 함수를 호출하려고합니다. 내 수업 MyClass의 예 :

package MyClass; 
use strict; 
use warnings; 

sub import{ 
     my $class = shift; 
     my ($caller) = caller(); 
     eval "sub ${caller}::myprot(\&);"; 
     eval "*${caller}::myprot = \&MyClass::myprot;";   
} 

sub myprot (&) { 
    my ($f) = @_; 
     $f->(); 
} 

1; 

나는 스크립트 main.pl에서 프로토 타입을 호출 할 :

use strict; 
use warnings; 

use MyClass; 

myprot { 
     print "myprot\n"; 
}; 

와 나는 오류가 점점 오전 :

Use of uninitialized value in subroutine entry at MyClass.pm line 14. 
Use of uninitialized value in subroutine entry at MyClass.pm line 14. 
Undefined subroutine &main::myprot called at main.pm line 8. 

그렇게하지를 정의되지 않은 서브 루틴 오류를 실제로 이해합니다. use을 사용하면 main.pl의 프로토 타입을 정의하는 import이 호출됩니다. 나는 또한 실제로 초기화되지 않은 값 오류를 이해하지 못한다. 나는 약간 설명을 위해 행복 할 것이다.

Answer 1

정말로 하시겠습니까?

문제는 큰 따옴표가 glob 할당에있는 백 슬래시를 먹게된다는 것입니다.

는

eval "*${caller}::myprot = \&MyClass::myprot;" 

eval "*${caller}::myprot = \\&MyClass::myprot;" 

해야하지만 당신의 코드를 디버깅달라고하지 마십시오!

Answer 2

해당 코드에는 여러 가지 스케치가 있습니다.

확인되지 않은 eval 사용은 실패하면 결코 알 수 없음을 의미합니다. eval은 eval "code" or die $@으로 사용해야합니다. 엄격하면 심볼 테이블을 엉망으로 만들 때 오류 메시지가 나타나기 때문에 오류가 발생합니다 (즉, *name = \&code).

eval을 내보내기 서브 루틴을 사용하면 잔인합니다. eval STRING은 잠재적 인 보안 구멍이므로 최후의 수단으로 사용해야합니다 (eval BLOCK은 괜찮습니다). 평가판을 사용하지 않고 기호 테이블을 조작 할 수 있지만 엄격하게 기호 참조를 사용하는 것은 바람직하지 않습니다.

my $caller = "foo"; 
*{"${caller}::myprot"} = \&MyClass::myprot; 
# Can't use string ("foo::myprot") as a symbol ref while "strict refs" in use... 

먼저 엄격한 설정을 해제해야합니다. 이것은 일반적으로 "앨리어싱"이라고합니다.

no strict 'refs'; 
*{$caller.'::myprot'} = \&myprot; 

프로토 타입을 미리 설정하지 않아도 별칭이 처리합니다.

이것은 모두 불필요한 것으로 밝혀졌으며,이를 위해 여러 가지 모듈이 있습니다. 가장 일반적인 것은 Exporter이며 Perl과 함께 제공됩니다. 이로 인해 사용자 지정 import이 필요하지 않습니다.

use Exporter 'import'; 
our @EXPORT = qw(myprot); 

다른 일반적인 팁 ...

클래스에서 클래스의 이름을 코딩 하드

(즉. \&MyClass::myprot 그냥 \&myprot해야한다)을 피해야한다. 클래스를 변경하거나 코드를 옮기는 것이 더 어려워집니다.

클래스와 내보내기 기능을 모두 갖춘 하이브리드 모듈은 사용하지 않는 것이 좋습니다. 그들은 사용하기 어렵고, 테스트하고, 문서화하고, 이상한 부작용을 일으킨다. myprot을 자체 모듈에 넣어야합니다.

Answer 3

당신은 수출업자를 찾고 있습니다.

package MyClass; 
use strict; 
use warnings; 

use Exporter qw(import); 

our @EXPORT = qw(myprot); 

sub myprot(&) { 
    my ($f) = @_; 
    $f->(); 
} 

1; 

나는 보통 @EXPORT_OK (use MyClass qw(myprot);의 사용을 필요로하는)보다는 기본적으로 수출을 사용합니다.