XSLT를 사용하여 XML 출력을 줄입니다.

Question

XSLT를 사용하여 입력 XML에서 출력 XML로 일부 XML 태그 만 선택하려면 어떻게해야합니까? 예를 입력 :

<Country value="USA"> 
    <State value="KY> 
     <City value="Hebron" /> 
     <City value="Lexington" /> 
     <City value="Owensboro" /> 
     <City value="Jonesville" /> 
    </State> 
    <State value="OH"> 
     <City value="Cincinnati" /> 
     <City value="Columbus" /> 
     <City value="Cleveland" /> 
     <City value="Jonesville" /> 
    </State> 
    <State value="IN" > 
     <City value="Indianapolis" /> 
    </State> 
</Country> 

그래서, 대신 국가/주 태그를 유지하고 만 헤브론 신시내티 복사?

예상 출력 :

<Country value="USA"> 
    <State value="KY> 
     <City value="Hebron" /> 
    </State> 
    <State value="OH"> 
     <City value="Cincinnati" /> 
    </State> 
</Country> 

Answer 1

다음 스타일 시트 :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()" /> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="City[not(@value='Hebron' or @value='Cincinnati')]" /> 
</xsl:stylesheet> 

을이 입력에 516,

:

가

<Country value="USA"> 
    <State value="KY"> 
     <City value="Hebron" /> 
    </State> 
    <State value="OH"> 
     <City value="Cincinnati" /> 
    </State> 
</Country> 

이 스타일은 변경되지 않은 출력에 불필요한 노드를 제외한 모든 복사 identity transform를 사용

<Country value="USA"> 
    <State value="KY"> 
     <City value="Hebron" /> 
     <City value="Lexington" /> 
     <City value="Owensboro" /> 
    </State> 
    <State value="OH"> 
     <City value="Cincinnati" /> 
     <City value="Columbus" /> 
     <City value="Cleveland" /> 
    </State> 
</Country> 

는 다음의 결과를 생성.

또 다른 예 또한 원하는 도시를하지 않는 State 요소를 제거 할 수 있습니다

. 이 스타일이 입력에 적용

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
    <xsl:template match="@*|node()"> 
     <xsl:copy> 
      <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:template> 
    <xsl:template match="City[not(@value='Hebron' or @value='Cincinnati')]"/> 
    <xsl:template 
      match="State[not(City[@value='Hebron' or @value='Cincinnati'])]"/> 
</xsl:stylesheet> 

:

<Country value="USA"> 
    <State value="KY"> 
     <City value="Hebron" /> 
     <City value="Lexington" /> 
     <City value="Owensboro" /> 
    </State> 
    <State value="OH"> 
     <City value="Cincinnati" /> 
     <City value="Columbus" /> 
     <City value="Cleveland" /> 
    </State> 
    <State value="MO"> 
     <City value="St. Louis" /> 
    </State> 
</Country> 

가 생산 :

<Country value="USA"> 
    <State value="KY"> 
     <City value="Hebron" /> 
    </State> 
    <State value="OH"> 
     <City value="Cincinnati" /> 
    </State> 
</Country> 

Answer 2

이 떠나 특정 도시 :

<xsl:template match="*|@*"> 
    <xsl:copy><xsl:apply-templates select="*|@*"/></xsl:copy> 
</xsl:template> 


<xsl:template match="City[@value != 'Hebron' and @value != 'Cincinnati']"/> 

이는 첫번째 도시 떠날 것이다 :

<xsl:template match="*|@*"> 
    <xsl:copy><xsl:apply-templates select="*|@*"/></xsl:copy> 
</xsl:template> 


<xsl:template match="City[position() &gt; 1]"/> 

Answer 3

은 여기 내 (아마 부적절한) 2.0 솔루션입니다. 도시는 매개 변수로 전달되는 정규 표현식입니다.

<xsl:stylesheet 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    version="2.0"> 

    <xsl:param name="Cities" select="'Cincinnati|Hebron'"/> 

    <xsl:template match="State"> 
    <xsl:if test="exists(City[matches(@value, $Cities)])"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:if> 
    </xsl:template> 

    <xsl:template match="State/City"> 
    <xsl:if test="matches(@value, $Cities)"> 
     <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
     </xsl:copy> 
    </xsl:if> 
    </xsl:template> 

    <xsl:template match="@*|node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@*|node()"/> 
    </xsl:copy> 
    </xsl:template> 

</xsl:stylesheet>