숫자가 증가하는 파일을 첨부 할 수있는 배치 파일

Question

디렉토리에서 파일을 가져 와서 전자 메일로 보낼 배치 파일을 작성하려고합니다. 그게 쉽지, 내가 겪고있는 문제는 이메일을 보내야하는 파일이 증가하는 숫자 또는 시간/날짜 스탬프를 가지고 있다는 것입니다. 분명히 시간 문제의 불일치로 인해 파일 이름을 증가하는 숫자로 변경할 수 있습니다. 내 문제는 디렉토리에서 가장 최신 인 파일을 지정하는 방법이나 파일 이름에서 가장 큰 번호를 갖는 파일을 지정하는 것입니다. 나는 잠시 동안 지금을 찾고 있었고 도움이 된 것을 발견하지 못했습니다.

@echo off 
setlocal 

set Port=465 
set SSL=True 
set From="email@blah.com" 
set To="email@blah.com" 
set Subject="Subject" 
set Body="Body" 
set SMTPServer="smtp.gmail.com" 
set User="username" 
set Pass="password" 
set fileattach="\\networklocation\filename.jpg" 

if "%~7" NEQ "" (
set From="%~1" 
set To="%~2" 
set Subject="%~3" 
set Body="%~4" 
set SMTPServer="%~5" 
set User="%~6" 
set Pass="%~7" 
set fileattach="%~8" 
) 

set "vbsfile=%temp%\email-bat.vbs" 
del "%vbsfile%" 2>nul 
set cdoSchema=http://schemas.microsoft.com/cdo/configuration 
echo >>"%vbsfile%" Set objArgs  = WScript.Arguments 
echo >>"%vbsfile%" Set objEmail  = CreateObject("CDO.Message") 
echo >>"%vbsfile%" objEmail.From  = %From% 
echo >>"%vbsfile%" objEmail.To  = %To% 
echo >>"%vbsfile%" objEmail.Subject = %Subject% 
echo >>"%vbsfile%" objEmail.Textbody = %body% 
if exist %fileattach% echo >>"%vbsfile%" objEmail.AddAttachment %fileattach% 
echo >>"%vbsfile%" with objEmail.Configuration.Fields 
echo >>"%vbsfile%" .Item ("%cdoSchema%/sendusing")  = 2 ' not local, smtp 
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpserver")  = %SMTPServer% 
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpserverport") = %port% 
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpauthenticate") = 1 ' cdobasic 
echo >>"%vbsfile%" .Item ("%cdoSchema%/sendusername")  = %user% 
echo >>"%vbsfile%" .Item ("%cdoSchema%/sendpassword")  = %pass% 
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpusessl")  = %SSL% 
echo >>"%vbsfile%" .Item ("%cdoSchema%/smtpconnectiontimeout") = 30 
echo >>"%vbsfile%" .Update 
echo >>"%vbsfile%" end with 
echo >>"%vbsfile%" objEmail.Send 

cscript.exe /nologo "%vbsfile%" 

echo email sent (if variables were correct) 

수년 동안이 사이트는 많은 도움을 주었으며 커뮤니티에 감사의 말씀을 전하고 싶습니다.

Answer 1

폴더에 .JPG 파일의 수천이있는 경우 다음 짧은 지연 될 (set fileattach="\\networklocation\filename.jpg"

for /f "delims=" %%a in ('dir "\\networklocation\*.jpg" /b /od') do set fileattach="\\networklocation\%%a" 

그것은 최신 파일을 선택 대신에 아래의 라인을 사용하거나 방법 B를 요청 :)

두 위치에서 \\networklocation을 변경하십시오.

Answer 2

여기에 내가 작성한 기능이 있습니다. David의 코드와 비슷하지만/o-d를 사용하여 발견 된 첫 번째 파일을 가져 와서 루프를 종료합니다. 디렉토리에 파일이 많으면 속도가 빨라집니다. 또한 최신 작성, 액세스 또는 작성을 원하면 쉽게 지정할 수 있습니다.

Call :getlatestfile "C:\files" "w" latest 
echo %latest% 
exit /b   


:getlatestfile <path> <c/a/w> <return> 
setlocal 
for /f %%b in ('dir "%~1" /b /o-d /t%~2') do (
set "latest=%%b" & goto :out) 
:out 
endlocal & set "%~3=%latest%"