varchar 값 '내 반환 값'을 데이터 유형 int로 변환 할 때 변환이 실패했습니다

Question

테이블에서 문자열을 검색 할 때이 간단한 SQL 문에서이 오류가 발생합니다.

메시지 245, 수준 16, 상태 1, 절차 prViewRequirements, 줄 18 varchar 값 '박사의 심장 평가 설문지'를 변환 할 때 변환하지 못했습니다. 데이터 유형 int.

/****** Object: StoredProcedure [dbo].[prViewRequirements] Script Date: 04/24/2013 15:44:49 ******/ 
SET ANSI_NULLS ON 
GO 
SET QUOTED_IDENTIFIER ON 
GO 
ALTER PROCEDURE [dbo].[prViewRequirements] 
    @WFRouteID int 

AS 

DECLARE 
@DocumentDescription VARCHAR(100) 

SELECT @DocumentDescription = DocumentDescription 
      FROM tbFollowOnTracking 
      WHERE WFRouteID = @WFRouteID 
      AND IsActive = 1 


      IF (@@ERROR <> 0) 
       GOTO ERRSP  

     RETURN @DocumentDescription 

ERRSP: 
    RETURN -1 

이유를 아는 사람이 있습니까?

Answer 1

int 대신 varchar를 반환하려고합니다.

RETURN @DocumentDescription 

하시기 바랍니다 중 하나

select @DocumentDescription 

을하거나 (권장) 출력 매개 변수

ALTER PROCEDURE [dbo].[prViewRequirements] 
    @WFRouteID int 
    , @DocumentDescription varchar(100) = null output 

UPDATE 사용 - 여기에 모든 절차 :

alter procedure dbo.prViewRequirements 
    @WFRouteID int 
    , @DocumentDescription varchar(100) = null output 
AS 

select @DocumentDescription = '' -- Init 

select @DocumentDescription = DocumentDescription 
from tbFollowOnTracking 
where WFRouteID = @WFRouteID 
and IsActive = 1 

return 0 
go 

/* Examples 
declare @DocumentDescription varchar(100) = '' 

exec dbo.prViewRequirements @WFRouteID = 10, @DocumentDescription = @DocumentDescription output 

select @DocumentDescription 
*/ 

Answer 2

이 하나를 시도를 -

ALTER PROCEDURE [dbo].[prViewRequirements] 

     @WFRouteID INT 
    , @DocumentDescription VARCHAR(100) OUTPUT 

AS BEGIN 

    SELECT @DocumentDescription = t.DocumentDescription 
    FROM dbo.tbFollowOnTracking t 
    WHERE t.WFRouteID = @WFRouteID 
     AND t.IsActive = 1 

    IF @DocumentDescription IS NULL 
     RETURN -1  

    RETURN 0 

END 

Answer 3

이 시도 :

alter procedure dbo.prViewRequirements 
    @WFRouteID int 
    , @DocumentDescription varchar(100) = null output 
AS 

BEGIN 
select @DocumentDescription = '' -- Init 

select @DocumentDescription = DocumentDescription 
from tbFollowOnTracking 
where WFRouteID = @WFRouteID 
and IsActive = 1 

END 

는 시저를 실행하여 아래와 같이 18 라인

DECLARE @res varchar(100) 
exec dbo.prViewRequirements @WFRouteID,@DocumentDescription=@res OUTPUT 
select @res