여러 줄을 병합하는 유닉스 쉘 스크립팅

Question

텍스트 파일이 하나 있습니다. 내용 :

game1 
game2 
game3 
game4 
/usr/local/games 
/usr/local/games 
/usr/local/games 
/usr/local/games 
10 
20 
30 
40 

출력 내가 원하는과 같은 것입니다 :

game1 /usr/local/games  10 
game2 /usr/local/games  20 
game3 /usr/local/games  30 
game4 /usr/local/games  40 

Answer 1

awk ' 
BEGIN { numRows = 4 } 
{ 
    rowNr = (NR-1)%numRows+1 
    colNr = ++colCnt[rowNr] 
    numCols = (colCnt[rowNr] > numCols ? colCnt[rowNr] : numCols) 
    val[rowNr,colNr] = $0 
} 
END { 
    for (rowNr=1; rowNr<=numRows; rowNr++) 
     for (colNr=1; colNr<=numCols; colNr++) 
      printf "%s%s", val[rowNr,colNr], (colNr < numCols ? OFS : ORS) 
} 
' file 
game1 /usr/local/games 10 
game2 /usr/local/games 20 
game3 /usr/local/games 30 
game4 /usr/local/games 40 

Answer 2

한 awk 사용하여 해결 방법 : n의 값을 변경할 수 있습니다

$ awk '{i=(NR-1)%n;a[i]=a[i](a[i]?"\t"$0:$0)}END{for(j=0;j<n;j++)print a[j]}' n=4 file 
game1 /usr/local/games  10 
game2 /usr/local/games  20 
game3 /usr/local/games  30 
game4 /usr/local/games  40 

은의 블록 사이즈와 일치합니다 입력.