다른 두 변수를 사용하여 SPSS에 변수를 만드시겠습니까?

Question

그래서 SPSS를 오랫동안 사용해 오지 않았고 두 가지 다른 변수를 사용하여 변수를 만드는 데 도움이 필요합니다.

나는 설문 조사를하고 각 개인에 대한 "세대수"변수와 "세대주와의 관계"(머리 = 1, 배우자 = 2, 자녀 = 3 등)의 변수를 가지고 있습니다. 각 가정의 세대주와의 관계를 사용하여 "가족 유형"의 변수를 만들고 싶습니다.

그래서, 뭔가 같은 :

If in the household there's only the head, then is 1 
If there's the head, spouse and/or children, then is 2 
If it's head plus any other type of relative, it's 3. 

예 :

가정용 Nº - 관계

1-1

1-2

1-3

"1"로 가정에서

는 머리가있는 것은 (1), 배우자 (2)와 아이 (3)는 2

나는 '돈은 "가족의 유형"될 수 있도록 이 작업을 수행하기 위해 사용할 명령이 SPPS인지는 알 수 없습니다. 누구든지 나를 도울 수 있습니까?

Answer 1

모든 가족 구성원에게 필요한 특성을 할당하고 if 문을 사용하여 패밀리 유형을 만드는 데는 AGGREGATE을 사용해야 할 것으로 생각됩니다. 그래서 당신과 비슷한 예제 데이터로 시작하십시오. 이렇게하면 일련의 패밀리가 긴 형식으로 작성됩니다.

data list free/house relation. 
begin data 
1 1 
1 2 
1 3 
2 1 
3 1 
3 2 
4 1 
4 3 
5 1 
5 2 
5 3 
5 3 
5 3 
end data. 
VALUE LABELS relation 
1 'Head' 
2 'Spouse' 
3 'Child'. 

여기에서 네 종류의 가족을 제안합니다. Single-No Children, Couple-No Children, Single-With Children 및 Couple-With Children이다. 이를 얻으려면 케이스 변수가 자녀 또는 배우자인지 여부를 나타내는 더미 변수를 만든 다음 가족 내에서 최소값을 취합하여 가족에게 배우자 또는 자녀가 있는지 여부를 나타내는 플래그를 제공합니다.

*Make flag for if have a spouse and if have a child. 
COMPUTE child = (relation EQ 3). 
COMPUTE spouse = (relation EQ 2). 
*Aggregate to get a flag for child or spouse. 
AGGREGATE 
    /OUTFILE=* MODE=ADDVARIABLES 
    /BREAK=house 
    /AnyChild = MAX(child) 
    /AnySpouse = MAX(spouse) 
    /NumChild=SUM(child) 
    /TotalFamSize=N. 

나는 하나가 SUM를 사용하여 어린이와 집합 명령에 N을 사용하여 전체 가족 크기의 총 수를 얻을 수있는 방법을 보여줍니다. 여기에서 일련의 if 문을 사용하여 여러 유형의 패밀리를 분류 할 수 있습니다.

*From here can make several fam categories using DO IF. 
DO IF TotalFamSize = 1. 
    COMPUTE FamType = 1. 
ELSE IF AnySpouse = 1 AND AnyChild = 0. 
    COMPUTE FamType = 2. 
ELSE IF AnySpouse = 0 and AnyChild = 1. 
    COMPUTE FamType = 3. 
ELSE IF AnySpouse = 1 and AnyChild = 1. 
    COMPUTE FamType = 4. 
END IF. 
VALUE LABELS FamType 
1 'Single - No Children' 
2 'Couple - No Children' 
3 'Single - Children' 
4 'Couple - Children'. 
EXECUTE. 

집계를 사용하여 전체 패밀리에 대한 통계를 얻는 논리는 생성하려는 통계 유형에 상관없이 적용 할 수 있어야합니다.