AppleScript에서 Xcode의 특정 버전을 어떻게 시작합니까?

Question

두 버전의 Xcode, Xcode 3.2.3 및 Xcode4 개발자 미리보기가 설치되어 있습니다. AppleScript로 3.2.3 버전이 선택되었는지 어떻게 확인합니까? 대신 단순히 이름으로 엑스 코드를 참조하는

Answer 1

, 즉 :

이

tell application "Xcode" 
    ... 
end tell 

당신은 또한 즉, 자사의 전체 POSIX 경로하여 응용 프로그램의 특정 버전을 참조 할 수 있습니다 :

tell application "/Developer/Applications/Xcode 3.2.3.app" 
    ... 
end tell 

는 또한 참조 AppleScript 언어 가이드 섹션은 application class입니다.

더 복잡한 솔루션은 시스템에 설치된 응용 프로그램의 모든 버전에 대해 시작 서비스 데이터베이스를 검색하는 작업입니다. 그런 다음 원하는 버전으로 프로그래밍 방식으로 프로그램을 선택할 수 있습니다.

property pLSRegisterPath : "/System/Library/Frameworks/CoreServices.framework/Versions/A/Frameworks/LaunchServices.framework/Versions/A/Support/lsregister" 
property pAppBundleID : "com.apple.Xcode" 
property pAppRequiredVersion : "3.2.3" 

set theAppPaths to every paragraph of (do shell script pLSRegisterPath & " -dump | grep --before-context=2 \"" & pAppBundleID & "\" | grep --only-matching \"/.*\\.app\"") 

set xcodeApp to missing value 
repeat with theAppPath in theAppPaths 
    try 
     if (version of application theAppPath) = pAppRequiredVersion then 
      set xcodeApp to application theAppPath 
      exit repeat 
     end if 
    end try 
end repeat 

if xcodeApp = missing value then 
    error "Needed application version not installed." 
end if 

using terms from application "Xcode" 
    tell xcodeApp 
     activate 
    end tell 
end using terms from 

Answer 2

다음과 같은 ID로 응용 프로그램을 시작할 수 있습니다. 어쩌면 두 버전의 ID가 다를 수 있습니다. 당신이 사용하여 응용 프로그램의 ID를 얻을 수 있습니다

tell application id "com.apple.AddressBook" 
    -- do something 
end tell 

...

tell application "Finder" to return id of (choose file)