XSLT에서 배열을 선언하고 반복하는 방법은 무엇입니까?

Question

필자의 요구 사항은 XSLT-를 사용하여 미국 내 드롭 다운 목록을 표시하고 인쇄은 '내 스타일 시트를 사용할 XML에서 선언 된 특정'에 '선택됨'입니다.

상태로 배열을 선언하고 반복 할 생각 이었지만 어떻게해야할지 모르겠다.

참고 :;

Answer 1

한 가지 방법은 스타일 시트로 상태 데이터를 포함하는 것입니다

<xsl:stylesheet version="1.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:my="whatever" 
    exclude-result-prefixes="my"> 

    <xsl:output indent="yes"/> 

    <!-- The value of the state you want to select, supplied in the input XML --> 
    <xsl:variable name="selected-state" select="/xpath/to/state/value"/> 

    <!-- You have to use a namespace, or the XSLT processor will complain --> 
    <my:states> 
    <option>Alabama</option> 
    <option>Alaska</option> 
    <!-- ... --> 
    <option>Wisconsin</option> 
    <option>Wyoming</option> 
    </my:states> 

    <xsl:template match="/"> 
    <!-- rest of HTML --> 
    <select name="state"> 
     <!-- Access the embedded document as an internal "config" file --> 
     <xsl:apply-templates select="document('')/*/my:states/option"/> 
    </select> 
    <!-- rest of HTML --> 
    </xsl:template> 

      <!-- Copy each option --> 
      <xsl:template match="option"> 
      <xsl:copy> 
       <!-- Add selected="selected" if this is the one --> 
       <xsl:if test=". = $selected-state"> 
       <xsl:attribute name="selected">selected</xsl:attribute> 
       </xsl:if> 
       <xsl:value-of select="."/> 
      </xsl:copy> 
      </xsl:template> 

</xsl:stylesheet> 

당신은 어떤 질문이 있으면 알려주세요 다음과 같이 자체와는 document('')를 사용하여 스타일 시트 문서에 액세스 할 수 있습니다.

Answer 2

이상적으로 당신은 당신의 XML 파일에서 국가의 목록을 저장 것이며, 단지 그들을 반복하는 XSLT를 사용) 더 많은 아이디어를 환영합니다.

업데이트 : 당신이 XML을 편집 할 수없는 경우, 두 번째 데이터 파일에서 데이터를로드 할 document function를 사용하여 볼 수 있었다 :이 작업을 수행하는