AS3에서 Main()의 다른 인스턴스를 실행하는 방법

Question

AS3에서 Main 함수의 새 인스턴스를 어떻게 실행 하시겠습니까? 기본적으로 프로그램이 프로그램의 끝 부분에 도달하면 프로그램이 처음부터 다시 실행되기를 원합니다. 마지막에 트리에서 모든 자식을 제거하고 첫 번째 방법을 다시 실행하는 방법에 대해 생각했지만 불필요하고 지저분 해 보입니다. 클래스는 Sprite를 확장합니다.

편집 : 사용자 지정 이벤트를 만들고 dispatchEvent을 사용하여 프로그램 끝에이 문제를 일으키는 데 약간의 문제가 있습니다. 이것은 아래의 현재 코드입니다.

전체 RunMain.as :

package 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 

    public class RunMain extends Sprite { 

     public function RunMain():void { 

      addEventListener(Event.ENTER_FRAME, loop); 
     } 

     private function loop(event:Event){ 

      removeEventListener(Event.ENTER_FRAME, loop); 
      dispatchEvent(new EndEvent(EndEvent.END_EVENT)); 
     } 

    } 
} 

전체 EndEvent.as : Main.as의

package 
{ 
    import flash.events.Event; 

    public class EndEvent extends Event 
    { 
     // Event types. 
     public static const END_EVENT:String = "event1"; 

     public function EndEvent(type:String = EndEvent.END_EVENT) 
     { 
      super(type); 
     } 

     override public function clone():Event { 
      // Return a new instance of this event with the same parameters. 
      return new EndEvent(type); 
     } 
    } 
} 

부품 : 내 메인 클래스 내부

public function Main() { 
    runMain = new RunMain(); 
    runMain.addEventListener(EndEvent.END_EVENT, onProgramFinish); 
    addChild(runMain); 

    init(); 
    otherMethods(); 
} 

public function onProgramFinish() { 
    removeChild(runMain); 

    runMain = null; 

    runMain = new RunMain() ; 
} 

, 나는 라인을 가지고 프로그램 끝의 onProgramFinish();.

현재 컴파일러를 실행할 때 오류가 발생합니다.
ArgumentError : 오류 # 1063 : Main/onProgramFinish()에서 인수 개수가 일치하지 않습니다.
예상 한 0은 1을 받았습니다.

계속 진행을 선택하면 프로그램이 정상적으로 실행되지만 끝날 때 새 인스턴스가 실행되지 않습니다.

Answer 1

사실 특수 클래스 컨테이너를 만들어 메인 클래스에서 정확히 바꿔야합니다 (새로 만들기 또는 삭제). 이 게임 클래스는 dispatch events 일 수 있으며 적어도 스프라이트는 이벤트를 보낼 수 있습니다. 커스텀 이벤트를 생성하여 상위 레벨과 상위 레벨로 전달하면 Main 클래스에서 액션을 수행 할 수 있습니다.

class Main extends Sprite { 
    public var game:Game ; 
    public function Main():void { 
    game = new Game(new Player(), "asd") ; 
    game.addEventListener(GameEvent.GAME_OVER, onGameOver) ; 
    addChild(game) ; 
    } 

    public function onGameOver(){ 
    removeChild(game) ; 
    //also you can try removing heavy children of game 
    game = null ; //Let garbage collector know about object without reference. 

    game = new Game(new Player(), "example") ; 
    } 
} 

public class Game extends Sprite { 

    public var hero:Hero = new Hero() ; 
    public function Game(player:Player, name:String):void { 

    addEventListener(Event.ENTER_FRAME, loop) ; 
    } 

    private function loop(event:Event){ 
    if (hero.hp == 0){ 
     removeEventListener(Event.ENTER_FRAME, loop) ; 
     dispatchEvent(new GameEvent(GameEvent.GAME_OVER)) ; 
    } 
    } 
} 

Answer 2

귀하의 이벤트 :

package { 
    import flash.events.Event; 

public class ProgramEvent extends Event 
{ 

    public static const FINISH:String = "Finished" ; 

    public function ProgramEvent(type:String, bubbles:Boolean=false, cancelable:Boolean=false) 
    { 
     super(type, bubbles, cancelable); 

    } 

    public override function clone():Event 
    { 
     return new ProgramEvent(type, bubbles, cancelable); 
    } 

    public override function toString():String 
    { 
     return formatToString("ProgramEvent", "type", "bubbles", "cancelable", "eventPhase"); 
    } 

} 

} 

RunMain :

package 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 

    public class RunMain extends Sprite { 

     public function RunMain():void { 

      addEventListener(Event.ENTER_FRAME, loop); 
     } 

     private function loop(event:Event){ 

      removeEventListener(Event.ENTER_FRAME, loop); 
      dispatchEvent(new ProgramEvent(ProgramEvent.FINISH)); 
     } 

    } 
} 

그리고 홈페이지 :

public function Main() { 
    startProgram() ; 

    init(); 
    otherMethods(); 
} 

public function onProgramFinish(event:ProgramEvent) { 
    runMain.removeEventListener(ProgramEvent.FINISH, onProgramFinish) ; 
    removeChild(runMain); 
    runMain = null; 
    startProgram() ; 
} 

public function startProgram(){ 
    runMain = new RunMain() ; 
    runMain.addEventListener(ProgramEvent.FINISH, onProgramFinish); 
    addChild(runMain); 
}