압연 총계에서 처리량을 계산하십시오.

Question

내 시스템에 카페인이 없는지 확실하지 않지만, 내 인생에서 올바른 방법이 무엇인지 알아낼 수 없습니다 (수학).

나는 수동으로 중지 될 때까지 구문 분석 된 ethtool -S의 값을 모두 'x'(이 테스트 동안 6 초)로 기록하는 스크립트를 가지고 있습니다. iterations 등 계산하는 방법에 대한 코드가 있지만 초당 평균 바이트를 올바르게 계산하는 방법을 알아낼 수 없습니다.

다음은 출력의 모습입니다 : 우리는 바이트가 모두 증가했다 볼 수 있듯이

Fri Jun 8 23:48:35 GMT 2012 {{{ 
============== Network Statistics =============== 
IFNAME  rx_bytes  tx_bytes 
eth0  27840111418  3083391508 
eth4  6153013050  18478875401 
eth5  686368648  238683883 
eth6  53863181321  2119523154 
eth7  23127231747  84602654827 
eth8  399517273166  1686004510 

Fri Jun 8 23:48:41 GMT 2012 {{{ 
============== Network Statistics =============== 
IFNAME  rx_bytes  tx_bytes 
eth0  27840118248  3083392896 
eth4  6153014438  18478876789 
eth5  686370036  238685271 
eth6  53863182709  2119524542 
eth7  23127238019  84602660337 
eth8  399519325260  1686018706 

, 나는 이것의 반복의 수천거야.

은 정확히입니다. 인터페이스별로 이러한 숫자를 완전히 계산하고 평균 초당 바이트 수를 계산합니다 (결과적으로 * 0.00000762939453을 통해 mbps로 이동합니다). 내가 해봤

모든 것은 지금까지 비참하게 ... 실패했습니다

\ 시간/인내심/도움을 주셔서 감사합니다!

편집 :: 내가 현재 라고 생각하는 것 내가해야 할 일은 데이터를 표준화하기 위해 rx/tx 바이트의 원래 값을 제거하는 것입니다. 초기 합계를 가져 오는 현재 (못생긴) 문자열은 다음과 같습니다.

int1_rx_bytes=`cat $logfile | grep $int1 | awk '{print $2}' | awk '{sum+=$1} END {printf "%f", sum}'` 

어디에서 뺄셈 목적으로 원래 번호를 삽입할까요? 참고로 이미 $ int1_orig_rx_bytes라는 변수가 있습니다

Answer 1

두 스크립트는 모두 테스트되지 않았습니다. 이동 평균의 경우

:

awk 'BEGIN { 
    period = 10 
    pcount=1 
} 
NR == 1 { 
    baserx = $2 
    basetx = $3 
} 
{ 
    rx[$1, pcount] = $2 - baserx 
    tx[$1, pcount] = $3 - basetx 
    ifaces[$1] 
    if (c >= period) { 
     rxsum = txsum = 0 
     for (iface in ifaces) { 
      for (i = 1; i <= period; i++) { 
       rxsum += rx[iface, i] 
       txsum += tx[iface, i] 
      } 
      print iface, rxsum/period, txsum/period 
     } 
    } else { 
     c++ 
    } 
    pcount = (pcount + 1) % period + 1 
}' 

편집 : 모든 항목의 평균

:

awk ' 
NR == 1 { 
    baserx = $2 
    basetx = $3 
} 
{ 
    rx[$1] += $2 - baserx 
    tx[$1] += $3 - basetx 
} 
END { 
    for (iface in rx) { 
     print iface, rx[iface]/NR, tx[iface]/NR 
    } 
}' 

항목이 출력이 보장되지 것이라고 순서. gawk이있는 경우이를 처리 할 정렬 함수를 추가하거나 sort 유틸리티를 사용할 수 있습니다.

편집 2 :

이 위의 두 번째 버전과 모든 종류의 문제를 해결합니다.

awk ' 
    BEGIN { 
     OFMT = "%.4f" 
    } 

    /^[[:blank:]]*$/ { next } 

    ! ($1 in prevrx) { 
     prevrx[$1] = $2 
     prevtx[$1] = $3 
     next 
    } 
    { 
     count[$1]++ 
     drx = $2 - prevrx[$1] 
     dtx = $3 - prevtx[$1] 
     rx[$1] += drx 
     tx[$1] += dtx 
     prevrx[$1] = $2 
     prevtx[$1] = $3 
    } 
    END { 
     for (iface in rx) { 
      print iface, rx[iface]/count[iface], tx[iface]/count[iface] 
     } 
}'