벡터에서 항목의 색인을 찾으려면 어떻게합니까?

Question

어떤 아이디어가 ????이어야합니까? 내장되어 있습니까? 이 작업을 수행하는 가장 좋은 방법은 무엇입니까?

(def v ["one" "two" "three" "two"]) 

(defn find-thing [ thing vectr ] 
    (????)) 

(find-thing "two" v) ; ? maybe 1, maybe '(1,3), actually probably a lazy-seq 

Answer 1

내장 :

user> (def v ["one" "two" "three" "two"]) 
#'user/v 
user> (.indexOf v "two") 
1 
user> (.indexOf v "foo") 
-1 

모든 경기에 대한 지수의 게으른 서열하려면 다음

user> (map-indexed vector v) 
([0 "one"] [1 "two"] [2 "three"] [3 "two"]) 
user> (filter #(= "two" (second %)) *1) 
([1 "two"] [3 "two"]) 
user> (map first *1) 
(1 3) 
user> (map first 
      (filter #(= (second %) "two") 
        (map-indexed vector v))) 
(1 3) 

Answer 2

난 내 자신의 질문에 대답을 시도했지만 브라이언의 비트를 더 나은 대답으로 나에게 그것을!

(defn indices-of [f coll] 
    (keep-indexed #(if (f %2) %1 nil) coll)) 

(defn first-index-of [f coll] 
    (first (indices-of f coll))) 

(defn find-thing [value coll] 
    (first-index-of #(= % value) coll)) 

(find-thing "two" ["one" "two" "three" "two"]) ; 1 
(find-thing "two" '("one" "two" "three")) ; 1 

;; these answers are a bit silly 
(find-thing "two" #{"one" "two" "three"}) ; 1 
(find-thing "two" {"one" "two" "two" "three"}) ; nil 

Answer 3

스튜어트 Halloway이 게시물 http://www.mail-archive.com/clojure@googlegroups.com/msg34159.html에 정말 좋은 대답을 주었다. 첫 번째 값을 잡아하려면

(use '[clojure.contrib.seq :only (positions)]) 
(def v ["one" "two" "three" "two"]) 
(positions #{"two"} v) ; -> (1 3) 

단지 결과에 first를 사용합니다.

(first (positions #{"two"} v)) ; -> 1 

편집 : clojure.contrib.seq 내가 간단한 구현 예제와 함께 내 대답을 업데이트 사라졌다 때문에 :

(defn positions 
    [pred coll] 
    (keep-indexed (fn [idx x] 
        (when (pred x) 
        idx)) 
       coll)) 

Answer 4

(defn find-thing [needle haystack] 
    (keep-indexed #(when (= %2 needle) %1) haystack)) 

하지만 인덱스 손보는에 대해 경고를하고 싶습니다 : 가장 자주 보다 적게 관용적이고 어색한 Clojure를 만들어 낼 것입니다.

Answer 5

나는 최근에 인덱스를 여러 번 찾아야 만 했었습니다. 문제를 접근하는 다른 방법을 찾는 것보다 쉬웠 기 때문에 제가 선택했습니다. 길을 따라 나는 Clojure 목록에 .indexOf (Object object, int start) 메소드가 없다는 것을 발견했다. clojure.contrib.seq/positions위한 http://dev.clojure.org/display/design/Where+Did+Clojure.Contrib+Go

출처 : 그래서 같은 문제를 다루었가 테이너를 누락으로 Clojure의 1.4 clojure.contrib.seq의로서는

(defn index-of 
"Returns the index of item. If start is given indexes prior to 
start are skipped." 
([coll item] (.indexOf coll item)) 
([coll item start] 
    (let [unadjusted-index (.indexOf (drop start coll) item)] 
    (if (= -1 unadjusted-index) 
    unadjusted-index 
    (+ unadjusted-index start))))) 

Answer 6

(따라서 positions 함수)를 사용할 수없는 그리고 그것의 종속 clojure.contrib.seq/indexed입니다 : 여기에 사용 가능한

(defn indexed 
    "Returns a lazy sequence of [index, item] pairs, where items come 
    from 's' and indexes count up from zero. 

    (indexed '(a b c d)) => ([0 a] [1 b] [2 c] [3 d])" 
    [s] 
    (map vector (iterate inc 0) s)) 

(defn positions 
    "Returns a lazy sequence containing the positions at which pred 
    is true for items in coll." 
    [pred coll] 
    (for [[idx elt] (indexed coll) :when (pred elt)] idx)) 

(positions #{2} [1 2 3 4 1 2 3 4]) => (1 5) 

: http://clojuredocs.org/clojure_contrib/clojure.contrib.seq/positions

Answer 7

여기에 loop 구조를 사용하고 실패시 nil을 반환하는 나의 공헌입니다.

나는 할 수있을 때 루프를 피하려고하지만이 문제에 적합하다고 보입니다.

(defn index-of [xs x] 
    (loop [a (first xs) 
     r (rest xs) 
     i 0] 
    (cond 
     (= a x) i 
     (empty? r) nil 
     :else  (recur (first r) (rest r) (inc i)))))