Access 2007 VBA에서 "파일 열기"대화 상자를 표시하는 방법?

Question

액세스 2007 VBA에서 열린 파일 (또는 파일 선택) 대화 상자를 표시하는 방법은 무엇입니까?

Excel에서와 같이 Application.GetOpenFileName을 사용해 보았지만이 함수는 Access에 존재하지 않습니다.

Answer 1

Renaud Bompuis의 답변에 대한 나의 의견이 엉망입니다.

실제로 런타임 바인딩을 사용할 수 있으며 11.0 개체 라이브러리에 대한 참조가 필요하지 않습니다.

다음 코드는 언급하지 않고 작동합니다

Dim f As Object 
Set f = Application.FileDialog(3) 
f.AllowMultiSelect = True 
f.Show 

MsgBox "file choosen = " & f.SelectedItems.Count 

참고 그 위의 작품을 잘 런타임도. 앨버트는 말했다 이미 무슨에

Answer 2

Access 2007에서는 Application.FileDialog 만 있으면됩니다. 샘플 말한다

' Requires reference to Microsoft Office 12.0 Object Library. ' 
Private Sub cmdFileDialog_Click() 
    Dim fDialog As Office.FileDialog 
    Dim varFile As Variant 

    ' Clear listbox contents. ' 
    Me.FileList.RowSource = "" 

    ' Set up the File Dialog. ' 
    Set fDialog = Application.FileDialog(msoFileDialogFilePicker) 

    With fDialog 

     ' Allow user to make multiple selections in dialog box ' 
     .AllowMultiSelect = True 

     ' Set the title of the dialog box. ' 
     .Title = "Please select one or more files" 

     ' Clear out the current filters, and add our own.' 
     .Filters.Clear 
     .Filters.Add "Access Databases", "*.MDB" 
     .Filters.Add "Access Projects", "*.ADP" 
     .Filters.Add "All Files", "*.*" 

     ' Show the dialog box. If the .Show method returns True, the ' 
     ' user picked at least one file. If the .Show method returns ' 
     ' False, the user clicked Cancel. ' 
     If .Show = True Then 

     'Loop through each file selected and add it to our list box. ' 
     For Each varFile In .SelectedItems 
      Me.FileList.AddItem varFile 
     Next 

     Else 
     MsgBox "You clicked Cancel in the file dialog box." 
     End If 
    End With 
End Sub 

으로, 당신이> 도구> 참조합니다 VBE IDE에서 Microsoft Access에서 12.0 개체 라이브러리에 대한 참조를 (이 있는지 확인 : 여기

는 액세스 문서의 예입니다 메뉴).

Answer 3

추가 :

이 코드 (다양한 샘플의 매시업)은 다른 이름으로 저장 대화 상자

Function getFileName() As String 
    Dim fDialog As Object 
    Set fDialog = Application.FileDialog(msoFileDialogSaveAs) 
    Dim varFile As Variant 

    With fDialog 
     .AllowMultiSelect = False 
     .Title = "Select File Location to Export XLSx :" 
     .InitialFileName = "jeffatwood.xlsx" 

    If .Show = True Then 
     For Each varFile In .SelectedItems 
     getFileName = varFile 
     Next 
    End If 
End With 
End Function 

Answer 4

나는 존 M은 영업 이익의에 대한 가장 좋은 대답을 가지고 동의를 할 수있는 기능을 제공합니다 문제. 생각은 명확히 밝혀지지 않았지만, 명백한 목적은 선택된 파일 이름을 얻는 것이었고 다른 대답은 카운트 또는 목록을 반환하는 것입니다. 그러나이 경우 msofiledialogfilepicker가 더 나은 옵션 일 수 있다고 덧붙입니다. 예 :

Dim f As object 
Set f = Application.FileDialog(msoFileDialogFilePicker) 
dim varfile as variant 
f.show 
with f 
    .allowmultiselect = false 
    for each varfile in .selecteditems 
     msgbox varfile 
    next varfile 
end with 

참고 : 다중 선택이 거짓이기 때문에 varfile의 값이 동일하게 유지됩니다 (단 하나의 항목이 어느 선택). 루프 밖에서 그 값을 동등한 성공으로 사용했습니다. 그러나 John M이 그랬던 것처럼 그것을하는 것이 더 나은 방법 일 것입니다. 또한 폴더 선택 도구를 사용하여 선택한 폴더를 가져올 수 있습니다. 나는 늦은 바인딩을 항상 선호하지만 개체가 기본 액세스 라이브러리에 기본이라고 생각하므로 여기서는 필요하지 않을 수도 있습니다.

Answer 5

나는 위와 비슷한 해결책을 가지고 있으며 파일 열기, 저장, 파일 선택을 위해 작동합니다. 나는 그것을 자체 모듈에 붙여 넣고 모든 Access DB에서 사용합니다. 코드에 따르면 Microsoft Office 14.0 Object Library가 필요합니다. 내가 생각하는 또 다른 옵션은 다음과 같습니다.

Public Function Select_File(InitPath, ActionType, FileType) 
    ' Requires reference to Microsoft Office 14.0 Object Library. 

    Dim fDialog As Office.FileDialog 
    Dim varFile As Variant 


    If ActionType = "FilePicker" Then 
     Set fDialog = Application.FileDialog(msoFileDialogFilePicker) 
     ' Set up the File Dialog. 
    End If 
    If ActionType = "SaveAs" Then 
     Set fDialog = Application.FileDialog(msoFileDialogSaveAs) 
    End If 
    If ActionType = "Open" Then 
     Set fDialog = Application.FileDialog(msoFileDialogOpen) 
    End If 
    With fDialog 
     .AllowMultiSelect = False 
     ' Disallow user to make multiple selections in dialog box 
     .Title = "Please specify the file to save/open..." 
     ' Set the title of the dialog box. 
     If ActionType <> "SaveAs" Then 
      .Filters.Clear 
      ' Clear out the current filters, and add our own. 
      .Filters.Add FileType, "*." & FileType 
     End If 
     .InitialFileName = InitPath 
     ' Show the dialog box. If the .Show method returns True, the 
     ' user picked a file. If the .Show method returns 
     ' False, the user clicked Cancel. 
     If .Show = True Then 
     'Loop through each file selected and add it to our list box. 
      For Each varFile In .SelectedItems 
       'return the subroutine value as the file path & name selected 
       Select_File = varFile 
      Next 
     End If 
    End With 
End Function