Maven의 속성 파일에서 enum을 생성하는 방법은 무엇입니까?

Question

원래 제목은 "개미를 사용하여 속성 파일에서 열거 형을 생성하는 방법"

모든 속성을 반복하고 모든 속성을 가진 enum 클래스를 생성하려고합니다.

사용자 정의 작업을 작성하는 것에 대해 생각하고 있지만 추가 병에 넣어야한다고 생각합니다.

메신저를 사용하여 메신저와 나는 generate-sources 단계에서 그것을하고 싶다.

Answer 1

비록 다소 Peter Tilemans에 동의하지만,이 문제로 인해 유혹을 받았으며 Groovy와 GMaven-Plugin을 사용하여 솔루션을 해킹했습니다. EDIT : GMaven의 가장 큰 장점은 먼저 플러그인을 만들지 않고도 Maven 객체 모델에 직접 액세스 할 수 있으며 Groovy의 전체 프로그래밍 능력이 있다는 것입니다.

이 경우 나는 src/main/groovy라는 실제 빌드 프로세스의 일부가 아닌 소스 폴더를 만드는 것이므로 jar/war 등에 기여하지 않을 것입니다. 거기 그루비 소스 파일을 넣을 수 있습니다, 그래서 이클립스 빌드를 변경하지 않고 자동 완성 등 그루비 소스 폴더로 그들을 사용할 수 있습니다.

그래서이 폴더에서 나는 세 개의 파일이 있습니다 EnumGenerator.groovy, enumTemplate.txt 및 enum.properties을 여기

그들이 (내가 단순화하기 위해 이런 짓을, 당신은 아마 특성이 다른 곳에서 파일을 얻을 것이다) :

EnumGenerator.groovy

import java.util.Arrays; 
import java.util.HashMap; 
import java.util.TreeMap; 
import java.io.File; 
import java.util.Properties; 

class EnumGenerator{ 

    public EnumGenerator(
     File targetDir, 
     File propfile, 
     File templateFile, 
     String pkgName, 
     String clsName 
    ) { 
     def properties = new Properties(); 
     properties.load(propfile.newInputStream()); 
     def bodyText = generateBody(new TreeMap(properties)); 
     def enumCode = templateFile.getText(); 
     def templateMap = [ body:bodyText, packageName:pkgName, className: clsName ]; 
     templateMap.each{ key, value -> 
           enumCode = enumCode.replace("\${$key}", value) } 
     writeToFile(enumCode, targetDir, pkgName, clsName) 
    } 

    void writeToFile(code, dir, pkg, cls) { 
     def parentDir = new File(dir, pkg.replace('.','/')) 
     parentDir.mkdirs(); 
     def enumFile = new File (parentDir, cls + '.java') 
     enumFile.write(code) 
     System.out.println("Wrote file $enumFile successfully") 
    } 

    String generateBody(values) { 

     // create constructor call PROPERTY_KEY("value") 
     // from property.key=value 
     def body = ""; 
     values.eachWithIndex{ 
      key, value, index -> 
       body += 
       ( 
        (index > 0 ? ",\n\t" : "\t") 
        + toConstantCase(key) + '("' + value + '")' 
       ) 
     } 
     body += ";"; 
     return body; 

    } 

    String toConstantCase(value) { 
     // split camelCase and dot.notation to CAMEL_CASE and DOT_NOTATION 
     return Arrays.asList( 
      value.split("(?:(?=\\p{Upper})|\\.)") 
     ).join('_').toUpperCase(); 
    } 

} 

enumTemplate.txt

package ${packageName}; 

public enum ${className} { 

${body} 

    private ${className}(String value){ 
     this.value = value; 
    } 

    private String value; 

    public String getValue(){ 
     return this.value; 
    } 

} 

enum.속성 여기

simple=value 
not.so.simple=secondvalue 
propertyWithCamelCase=thirdvalue 

가 치어 구성입니다 :

<plugin> 
    <groupId>org.codehaus.groovy.maven</groupId> 
    <artifactId>gmaven-plugin</artifactId> 
    <version>1.0</version> 
    <executions> 
     <execution> 
      <id>create-enum</id> 
      <phase>generate-sources</phase> 
      <goals> 
       <goal>execute</goal> 
      </goals> 
      <configuration> 
       <scriptpath> 
        <element>${pom.basedir}/src/main/groovy</element> 
       </scriptpath> 
       <source> 
        import java.io.File 
        import EnumGenerator 

        File groovyDir = new File(pom.basedir, 
         "src/main/groovy") 
        new EnumGenerator(
         new File(pom.build.directory, 
          "generated-sources/enums"), 
         new File(groovyDir, 
          "enum.properties"), 
         new File(groovyDir, 
          "enumTemplate.txt"), 
         "com.mycompany.enums", 
         "ServiceProperty" 
        ); 

       </source> 
      </configuration> 
     </execution> 
    </executions> 
</plugin> 

그리고 여기 결과입니다 : 템플릿을 사용하여

package com.mycompany.enums; 

public enum ServiceProperty { 

    NOT_SO_SIMPLE("secondvalue"), 
    PROPERTY_WITH_CAMEL_CASE("thirdvalue"), 
    SIMPLE("value"); 

    private ServiceProperty(String value){ 
     this.value = value; 
    } 

    private String value; 

    public String getValue(){ 
     return this.value; 
    } 

} 

, 당신은 당신의 요구에 맞게 열거를 사용자 정의 할 수 있습니다 . gmaven은 maven에 groovy를 내장하고 있기 때문에 아무 것도 설치하거나 빌드 구성을 변경할 필요가 없습니다.

기억해야 할 점은 buildhelper 플러그인을 사용하여 빌드에 add the generated source folder을 사용해야한다는 것입니다.

Answer 2

다시 생각해 보시기 바랍니다.

구성 파일에서 오는 값에 대해 하드 코딩이 끝날 위험이 있으며 언제든지 변경 될 수 있습니다.

속성 파일을 읽는 HashMap 또는 BidiMap 주위의 약간의 래퍼 클래스가 거의 동일한 이점을 얻게 될 것이며 나중에 개발자는 작은 변경으로 인해 gazillion 컴파일 오류가 발생하는 이유를 모르는 채로 자신의 머리카락을 꺼내지 않을 것이라고 생각합니다. 프로퍼티 파일

나는 코드 생성에 대한 내 몫을했습니다. 파서와 프로토콜 처리기에 유용하지만, 다른 모든 유스 케이스의 경우 타임 봄을 똑딱 거리며 사용하고 있습니다.