공통 필드를 사용하여 여러 행을 한 행에 병합

Question

다음과 같은 파일이 있습니다.

1111|p1 
1111|p2 
1111|p3 
1111|p4 
1111|p5 
1111|p6 
2222|p1 
2222|p2 

등등 ..

한명 (1111)의 행 당 하나 개의 제품이있다.

나는 그렇게 P5이 허용 된 경우에만 개까지 하나의 행에 대해, 남은 ROW2에 와야한다

1111|row1|p1|p2|p3|p4|p5 
1111|row2|p6 
2222|p1|p2 
3333|p1|p2|p3 

아래와 같이 출력이 필요합니다. 펄에서 이런 식으로 출력하는 것을 도와주세요.

Answer 1

각 사람을 위해 제품을 저장하는 배열의 해시를 사용

#!/usr/bin/perl 
use warnings; 
use strict; 

my %owns; 
while (<DATA>) { 
    chomp; 
    my ($person, $product) = split /\|/; 
    push @{ $owns{$person} }, $product; 
} 

for my $person (keys %owns) { 
    my @products = @{ $owns{$person} }; 
    if (@products > 5) { 
     my $row = 1; 
     while (@products) { 
      my @five = splice @products, 0, 5; 
      print join '|', $person, "row$row", @five; 
      print "\n"; 
      $row++; 
     } 
    } else { 
     print join '|', $person, @products; 
     print "\n"; 
    } 
} 


__DATA__ 
1111|p1 
1111|p2 
1111|p3 
1111|p4 
1111|p5 
1111|p6 
2222|p1 
2222|p2 

Answer 2

아무것도 영리하려고 프로그래머보다 더 나쁜 없습니다.

use strict; 
use warnings; 

my $data = do {local $/; <DATA>}; 

$data =~ s{^((\d+)\|.*\n(?:\2\|.*\n)+)}{ 
    my ($whole, $header) = ($1, $2); 
    my @nums = map {/\|(.*)/} split "\n", $whole; 
    my $return = ''; 
    if (@nums > 5) { 
     for (my $i = 1; @nums; $i++) { 
      $return .= join('|', $header, "row$i", splice @nums, 0, 5) . "\n"; 
     } 
    } else { 
     $return = join('|', $header, @nums) . "\n"; 
    } 
    $return; 
}emg; 

print $data; 

__DATA__ 
1111|p1 
1111|p2 
1111|p3 
1111|p4 
1111|p5 
1111|p6 
2222|p1 
2222|p2 

출력 :

그러나, 다음과 같은 필터를 수행하는 정규 표현식을 사용

1111|row1|p1|p2|p3|p4|p5 
1111|row2|p6 
2222|p1|p2