XSLT는 생성 된 출력에서 ​​빈 노드를 제거하고 출력은 변수에 설정합니다.

Question

생성 된 출력 및 변수에 설정된 출력에서 ​​빈 노드를 제거하는 데 도움을주십시오.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
       xmlns:user="http://www.contoso.com" 
       version="1.0"> 
    <xsl:variable name="books"> 
    <header> 
    <book author="Michael Howard">Writing Secure Code</book> 
    <book author="Michael Kay">XSLT Reference</book> 
    </header> 
    <item> 
     <item1>item1</item1> 
     <item2></item2>//remove this empty tag 
     <item3></item3>//remove this empty tag 
    </item> 
    <summary> 
     <summary1> 
     <sum1>SUB1</sum1> 
     <sum2></sum2> //remove this empty tag 
     </summary1> 
     <summary2>Summary2</summary2> 
     <summary3>Summ3</summary3> 
    </summary> 
    </xsl:variable> 

    <xsl:template match="/"> 
    <xsl:value-of select="$books"/>  
     <xsl:for-each select="msxsl:node-set($books)/node()">     
      <xsl:apply-templates/> 
      <!--select="ms:node-set($completeDocument[1])/node()"/>-->   
     </xsl:for-each> 
    </xsl:template> 
    <xsl:template match= "*[not(@*|*|comment()|processing-instruction()) and normalize-space()='']"/> 
</xsl:stylesheet> 

출력

<?xml version="1.0" encoding="utf-8"?>Writing Secure CodeXSLT Referenceitem1item2SUB1sub2Summary2Summ3Writing Secure CodeXSLT Referenceitem1item2SUB1sub2Summary2Summ3 

예상 출력

<header> 
     <book author="Michael Howard">Writing Secure Code</book> 
     <book author="Michael Kay">XSLT Reference</book> 
     </header> 
     <item> 
      <item1>item1</item1> 
     </item> 
     <summary> 
      <summary1> 
      <sum1>SUB1</sum1> 
      </summary1> 
      <summary2>Summary2</summary2> 
      <summary3>Summ3</summary3> 
     </summary> 

예상 출력을 만들어 내고 빈 노드를 제거 보여준다 다음 I는 XSLT를 만들었다.

Answer 1

특정 요소가 복사되지 않도록 보장하는 템플릿을 작성했지만 해당 접근 방식을 사용하려면 복사 할 노드를 복사하고 처리를 계속하는 ID 변환 템플릿을 추가해야합니다. 그렇지 않으면 요소 노드를 복사하지 않고 자식 노드를 처리하고 텍스트 노드 만 출력하는 기본 제공 템플릿 만 있습니다.

그래서 당신은

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
       xmlns:msxsl="urn:schemas-microsoft-com:xslt" 
       xmlns:user="http://www.contoso.com" 
       exclude-result-prefixes="xsl msxsl user" 
       version="1.0"> 
    <xsl:variable name="books"> 
    <header> 
    <book author="Michael Howard">Writing Secure Code</book> 
    <book author="Michael Kay">XSLT Reference</book> 
    </header> 
    <item> 
     <item1>item1</item1> 
     <item2></item2>//remove this empty tag 
     <item3></item3>//remove this empty tag 
    </item> 
    <summary> 
     <summary1> 
     <sum1>SUB1</sum1> 
     <sum2></sum2> //remove this empty tag 
     </summary1> 
     <summary2>Summary2</summary2> 
     <summary3>Summ3</summary3> 
    </summary> 
    </xsl:variable> 

    <xsl:template match="/"> 
    <xsl:apply-templates select="msxsl:node-set($books)/node()"/> 
    </xsl:template> 

    <xsl:template match="@* | node()"> 
    <xsl:copy> 
     <xsl:apply-templates select="@* | node()"/> 
    </xsl:copy> 
    </xsl:template> 

    <xsl:template match= "*[not(@*|*|comment()|processing-instruction()) and normalize-space()='']"/> 
</xsl:stylesheet>