Inno Setup 파스칼 스크립트에서 문자열의 너비와 높이 가져 오기

Question

파스칼 스크립트에서 문자열의 너비와 높이를 얻을 수 있습니까?

예 : 여기

var 
    S: String; 

S := 'ThisIsMyStringToBeChecked' 

I는 현재의 폰트 크기와 폰트에 따른 높이 및 폭을 반환해야한다.

How to get TextWidth of string (without Canvas)?을 읽었지 만 Inno Setup Pascal 코드로 변환 할 수 없습니다.

나는 캡션의 문자열의 폭이 TLabel.Width을 초과 할 때이 측정 (폭과 높이) clRed와 'Too Long To Display' 같은 TLabel.Caption을 변경하고 싶습니다.

미리 감사드립니다. TNewStaticText (안 TLabel)에 대한

Answer 1

다음 작품 :

type 
    TSize = record 
    cx, cy: Integer; 
    end; 

function GetTextExtentPoint32(hdc: THandle; s: string; c: Integer; 
    var Size: TSize): Boolean; 
    external 'GetTextExtentPoint32W@Gdi32.dll stdcall'; 
function GetDC(hWnd: THandle): THandle; 
    external 'GetDC@User32.dll stdcall'; 
function SelectObject(hdc: THandle; hgdiobj: THandle): THandle; 
    external 'SelectObject@Gdi32.dll stdcall'; 

procedure SmartSetCaption(L: TNewStaticText; Caption: string); 
var 
    hdc: THandle; 
    Size: TSize; 
    OldFont: THandle; 
begin 
    hdc := GetDC(L.Handle); 
    OldFont := SelectObject(hdc, L.Font.Handle); 
    GetTextExtentPoint32(hdc, Caption, Length(Caption), Size); 
    SelectObject(hdc, OldFont); 

    if Size.cx > L.Width then 
    begin 
    L.Font.Color := clRed; 
    L.Caption := 'Too long to display'; 
    end 
    else 
    begin 
    L.ParentFont := True; 
    L.Caption := Caption; 
    end; 
end;