Perl에서 배열의 여러 요소를 반복 할 수 있습니까?

Question

N의 배열로 구문 분석하기 위해 split을 사용하는 CSV 파일이 있습니다. 여기에서 N은 3의 배수입니다.

내가 파이썬이

foreach my ($a, $b, $c) (@d) {} 

비슷한 할 수있는 방법이 있나요?

Answer 1

당신은 List::MoreUtils::natatime를 사용할 수있는 문서에서 :.

my @x = ('a' .. 'g'); 
my $it = natatime 3, @x; 
while (my @vals = $it->()) { 
    print "@vals\n"; 
} 

natatime는 XS에서 구현

당신이 효율성을 선호한다, 그래서 그냥 설명을 위해, 여기에서이 세 가지를 구현하는 방법이다. 펄 요소의 반복자 발생기 :

#!/usr/bin/perl 

use strict; use warnings; 

my @v = ('a' .. 'z'); 

my $it = make_3it(\@v); 

while (my @tuple = $it->()) { 
    print "@tuple\n"; 
} 

sub make_3it { 
    my ($arr) = @_; 
    { 
     my $lower = 0; 
     return sub { 
      return unless $lower < @$arr; 
      my $upper = $lower + 2; 
      @$arr > $upper or $upper = $#$arr; 
      my @ret = @$arr[$lower .. $upper]; 
      $lower = $upper + 1; 
      return @ret; 
     } 
    } 
} 

Answer 2

@z=(1,2,3,4,5,6,7,8,9,0); 

for(@tuple=splice(@z,0,3); @tuple; @tuple=splice(@z,0,3)) 
{ 
    print "$tuple[0] $tuple[1] $tuple[2]\n"; 
} 

는 생산 : 쉽게

1 2 3 
4 5 6 
7 8 9 
0 

Answer 3

하지 않습니다. 당신은 배열 참조로 배열에 요소를 밀어, @d 세 가지 요소 튜플의 배열을 더 나을 것 :

foreach my $line (<>) 
    push @d, [ split /,/, $line ]; 

(당신이 정말로 CPAN에서 CSV 모듈 중 하나를 사용한다고 그 제외 .

Answer 4

나는 CPAN 내 모듈 List::Gen에서이 문제를 해결.

use List::Gen qw/by/; 

for my $items (by 3 => @list) { 

    # do something with @$items which will contain 3 element slices of @list 

    # unlike natatime or other common solutions, the elements in @$items are 
    # aliased to @list, just like in a normal foreach loop 

} 

당신은 또한 by을 구현하기 위해 List::Gen 사용하는 mapn 기능을 가져올 수 :

use List::Gen qw/mapn/; 

mapn { 

    # do something with the slices in @_ 

} 3 => @list; 

Answer 5

my @list = (qw(one two three four five six seven eight nine)); 

while (my ($m, $n, $o) = splice (@list,0,3)) { 
    print "$m $n $o\n"; 
} 

이 출력 : 사용하지 마십시오

one two three 
four five six 
seven eight nine