XSLT 문제 : 아니요 출력에 태그가 없습니다.

Question

저는 XSL 변환을 고수하고 하루 종일 많은 것을 시도했습니다. 분명히 나는 ​​이것에 대한 전문가가 아니다.

내 XSL 파일의 문제점을 이해하도록 도와 줄 수 있습니까?

이것은 내 원본 XML입니다.

<?xml version="1.0" encoding="UTF-8"?> 
<PublishPFTEST xmlns="http://www.ibm.com/maximo" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" creationDateTime="2017-08-18T17:20:13-03:00" transLanguage="EN" baseLanguage="EN" messageID="7584270.1503087614245122357" maximoVersion="7 6 20161014-1020 V7606-50" event="1"> 
    <PFTESTSet> 
    <WORKORDER action="Add"> 
     <ASSETNUM>MPC1234</ASSETNUM> 
     <DESCRIPTION>WOTEST</DESCRIPTION> 
     <WONUM>WO123</WONUM> 
     <SITEID>BEDFORD</SITEID> 

    </WORKORDER> 
    </PFTESTSet> 
</PublishPFTEST> 

내 XSL 파일 :

<?xml version="1.0" encoding="UTF-8" ?> 

<xsl:stylesheet version="1.0" xmlns="http://www.ibm.com/maximo" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 
    <xsl:output method="xml" indent="yes"/> 
    <xsl:template match="/"> 
     <TemplateSet> 
      <xsl:for-each select="/PublishPFTEST/PFTESTSet/WORKORDER"> 
       <asset> 
        <xsl:value-of select="ASSETNUM"/> 
       </asset> 
       <desc> 
        <xsl:value-of select="DESCRIPTION"/> 
       </desc> 

      </xsl:for-each> 
      <xsl:apply-templates/> 
     </TemplateSet> 
    </xsl:template> 
</xsl:stylesheet> 

그리고이 변환 된 XML 파일 ... 그것은 다른 데이터없이 XML 태그를 보여줍니다.

<?xml version="1.0" encoding="utf-8"?> 
<TemplateSet xmlns="http://www.ibm.com/maximo" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"> 


     MPC1234 
     WOTEST 
     WO123 
     BEDFORD 



</TemplateSet> 

가짜 질문은 죄송합니다.

Answer 1

XSLT's built-in template rules 때문에 모든 텍스트가 출력에 표시됩니다. 이 문제를 해결하려면 <xsl:apply-templates/>을 제거해야하므로 다른 처리는 수행되지 않습니다.

xsl:for-each이 아무 것도 선택하지 않기 때문에 새로운 XML 요소가 출력되지 않습니다. XML이 기본 네임 스페이스 http://www.ibm.com/maximo을 사용하고 있기 때문입니다. 네임 스페이스를 접두사에 바인딩하고 XPath에서 사용할 수 있습니다. 두 제안

예

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:m="http://www.ibm.com/maximo" 
    exclude-result-prefixes="m"> 
    <xsl:output method="xml" indent="yes"/> 

    <xsl:template match="/"> 
    <TemplateSet> 
     <xsl:for-each select="/m:PublishPFTEST/m:PFTESTSet/m:WORKORDER"> 
     <asset> 
      <xsl:value-of select="m:ASSETNUM"/> 
     </asset> 
     <desc> 
      <xsl:value-of select="m:DESCRIPTION"/> 
     </desc> 
     </xsl:for-each> 
    </TemplateSet> 
    </xsl:template> 

</xsl:stylesheet>