Perl을 사용하여 디렉토리에 일반 파일 목록 만 표시하려면 어떻게합니까?

Question

나는 Perl에서 디렉토리의 일반 파일을 나열하는 방법을 찾고있다. 파일 만, 디렉토리는 없습니다.

Answer 1

당신은 -f 파일 테스트 연산자와 함께 opendir, readdir 및 closedir 기능을 사용해야합니다

opendir(my $dh, $some_dir) || die $!; 
while(my $f = readdir $dh) { 
    next unless (-f "$some_dir/$f"); 
    print "$some_dir/$f\n"; 
} 
closedir $dh; 

Answer 2

readdir 연산자가 필요합니다.

예를 들어

:

#! /usr/bin/perl 

use warnings; 
use strict; 

my $dir = "/tmp/foo"; 
opendir my $dh, $dir 
    or die "$0: opendir: $!"; 

while (defined(my $name = readdir $dh)) { 
    next unless -f "$dir/$name"; 
    print "$name\n"; 
} 

그것을 실행 : 당신이 볼 수 있듯이

$ ls -F /tmp/foo 
a b c d/ 

$ ./prog.pl 
b 
c 
a

는, 이름이 필요하지 않다가 파일 시스템에 물리적으로 저장되어있는 순서에 나와 정렬.

당신은 또한 당신이 결과에서 디렉토리를 제거해야합니다

print map { s!^.*/!!; "$_\n" } 
     grep !-d $_ => 
     </tmp/foo/*>; 

주에서와 글로브 연산자를 사용할 수있는, 더러운 빠른 및-경로를 이동하려면, 그리고 글로브 연산자는하지 않습니다 이름이 점으로 시작하는 파일을 리턴합니다.

Answer 3

사용 File::Find. 그것은 핵심 모듈입니다.

use File::Find; 
find(\&wanted, @directories_to_search); 
sub wanted 
{ 
    my $file = shift; 
    return unless (-f $file); 
    #process file 
} 

Answer 4

파일 테스트 "연산자"(실제로는 함수)를 사용하여 원하는 파일 종류를 확인할 수 있습니다. 현재 디렉토리가 그렙와 파일 글로브 사용 검사 할 간단한 경우

: 그렇지 않으면

my @files = grep -f, <*>; 

을, 당신은 디렉토리 핸들을 작동 할 수 있습니다

opendir my $dh, $dirpath; 

my @files = grep -f, readdir($dh); 

closedir $dh; 

opendir를 참조하십시오, readdir, closedir, -X 및 grep.

Answer 5

디렉토리에있는 모든 파일을 나열하는 또 다른 방법은 CPAN 모듈 File::Slurp에서 read_dir 기능을 사용하는 것입니다

use strict; 
use warnings; 
use File::Slurp qw(read_dir); 

my $dir = './'; 
my @files = grep { -f } read_dir($dir); 

그것은 당신을 위해 검사를했던 opendir 수행합니다. "숨겨진"파일 (점으로 시작하는 파일)이 포함됩니다. 이것은 지정된 디렉토리의 서브 디렉토리에있는 파일을 재귀 적으로 나열하지 않습니다.

CPAN에서

Answer 6

File::Find::Rule는이 완전히 사소한 수 있습니다 :

use File::Find::Rule; 
my @files = File::Find::Rule->file->in($directory); 

이 지정된 디렉토리 또는 하위 디렉토리의 모든 파일을 찾습니다. 나는 극도의 유연성과 단순성의 결합 때문에 이것을 추천한다.