액세스 할 때 연결된 테이블 새로 고침

Question

안녕하세요. 네트워크에서 독립 실행 형 PC에있는 주 액세스 데이터베이스를 가지고 있고 네트워크에 연결된 테이블이있는 액세스 데이터베이스가 독립형 PC에 다시 연결되어 있습니다. 필자는 독립형 PC에 네트워크 공유를 만들고 경로를 통해 테이블을 연결하여 테이블을 연결했습니다. 데이터베이스를 열 때 링크 된 테이블을 자동으로 업데이트하도록 설정할 수 있습니까? 벤

Answer 1

하실 수 있습니다. 시작시 실행되는 작은 체크 양식 (시작 옵션을 통해 설정)을 사용하고 연결된 테이블을 포함하여 다양한 항목을 검사하는 것이 편리하다는 것을 자주 발견합니다. 이를 위해 연결된 테이블 목록을 TableDefs 컬렉션을 반복하여 얻을 수 있지만 로컬 컴퓨터에 연결된 테이블의 테이블을 보유하고 있지만 목록을 유지하는 것이 약간 안전하다고 생각합니다.

체크 폼은 모든 링크를 검사 할 수 있으며 링크가 손상되었거나 누락 된 경우 사용자에게 새 위치를 요청하거나 고정 된 위치를 사용하도록 요청할 수 있습니다. 문제가 발견되지 않으면 양식 자체를 닫고 메뉴 나 다른 양식을 열 수 있습니다.

다음

CurrentDB.TableDefs("TableName").Connection 

몇 가지 더주의 사항 :

Sub RelinkTables(Optional strConnect As String = "") 
Dim db As DAO.Database 
Dim rs As DAO.Recordset 
Dim strSQL 
Dim tdf As DAO.TableDef 

On Error GoTo TrapError 

    Set db = CurrentDb 

    If strConnect = "" Then 
     ''Where Me.txtNewDataDirectory is a control on the check form 
     strConnect = "MS Access;PWD=databasepassword;DATABASE=" & Me.txtNewDataDirectory 
    End If 

    ''Table of tables to be linked with two fields TableName, TableType 
    Set rs = CurrentDb.OpenRecordset("Select TableName From sysTables " _ 
      & "WHERE TableType = 'LINK'") 

    Do While Not RS.EOF 
     ''Check if the table is missing 
     If IsNull(DLookup("[Name]", "MSysObjects", "[Name]='" & rs!TableName & "'")) Then 
      Set tdf = db.CreateTableDef(RS!TableName, dbAttachSavePWD, _ 
       rs!TableName, strConnect) 
      ''If the table is missing, append it 
      db.TableDefs.Append tdf 
     Else 
      ''If it exists, update the connection 
      db.TableDefs(rs!TableName).Connect = strConnect 
     End If 
     db.TableDefs(rs!TableName).RefreshLink 
     RS.MoveNext 
    Loop 

    Set db = Nothing 
    RS.Close 
    Set RS = Nothing 


Exit_Sub: 
    Exit Sub 

TrapError: 
    HandleErr Err.Number, Err.Description, "Relink Tables" 

End Sub