C에서이 기계 코드는 어떻게 생겼을까요?

Question

나는 지난 4 일 동안 힘들어했던이 기계 코드를 가지고있다. 그러나 나는 그것을 잡을 수 없다.

pushl %ebp 
    movl %esp, %ebp 
    jmp .L3 
L4: 
    addl $3,8(%ebp) 

L3: 
    movl 8(%ebp),%eax // having issues here 
    movzbl (%eax),%eax//here 
    cmpb $1,%al// and here 
    je .L5 
    cmpl 12(%ebp),%eax 
    jne .L4 
    movl $8,%eax 
.L5: leave 
    ret 

여기에 솔루션에서 내 시도는 다음과 같습니다

int main(int s, char *t){ 
    while (s != 1) { 
     if (s == *t){ 
      s = 8; 
     } 
     else{s+=3;} 
    } 
    return; 
} 

내가 올바르게 접근하고있어 경우에 누군가가 말해 줄래? 내가 올바른 방향을 가리키는 데 도움이되지 않는다면?

Answer 1

기능은 그들이 인수 있음을 나타냅니다하는 중 초기화하지 않고 8(%ebp) 및 12(%ebp) 참조하기 때문에 __cdecl 것으로 보인다. arg1 및 arg2이라고 각각 부릅니다.

우리는 어셈블리 주석을 달 수 있습니다 : C 코드에서

/* Function prologue */ 
    pushl %ebp 
    movl %esp, %ebp 

    jmp .L3 
L4: 
    /* Move to next loop iteration */ 
    addl $3, arg1 

L3: 
    /* Copy value of arg1 to %eax */ 
    movl arg1, %eax 
    /* (%eax) means to dereference %eax (as a memory address). 
     movzbl means to load a single byte and zero-extend to the rest of the register. 
     Therefore, the byte at address %eax is put into %eax. */ 
    movzbl (%eax), %eax 
    /* Compare the low byte of %eax against 1 */ 
    cmpb $1, %al 
    /* If equal, exit (%eax = 1) */ 
    je .L5 
    /* Compare %eax against arg2 */ 
    cmpl arg2, %eax 
    /* If not equal, keep looping */ 
    jne .L4 

    /* Otherwise, if it was equal, we quit and return %eax = 8 */ 
    movl $8,%eax 
.L5: leave 
    ret 

, 이것은

여기

int fn(unsigned char *ptr, int sentinel) { 
    while(1) { 
     unsigned char c = *ptr; 
     if(c == 1) return c; 
     if(c == sentinel) return 8; 
     ptr += 3; 
    } 
} 

Answer 2

이와 비슷한 CDECL 호출 표준을 가정합니다.

int fn(int s, int t){ 
    for(;*(char*)s != 1 && s != t;s += 3); 
    if(s == t) 
     return 8; 
    else 
     return s; 
} 

여기에 설명하지 않은 내용이 있습니다.

movl 8(%ebp),%eax // Load s from stack into register eax. 
movzbl (%eax),%eax // Load a byte from the address in eax (s) and set the higher 3 bytes of eax to 0. 
cmpb $1,%al // Compare that byte loaded to 1. 

Answer 3

은 분해의 주석이 달린 버전이된다 :이에서

pushl %ebp  // save frame pointer 
    movl %esp, %ebp // setup new stack frame 

    // The stack frame looks like this: 
    // 0(%ebp) : previous frame pointer 
    // 4(%ebp) : return address 
    // 8(%ebp) : unsigned char *arg1 
    // 12(%ebp) : int arg2 

    jmp .L3    // jump to loop body 
L4: 
    addl $3,8(%ebp)  // arg1 += 3 

L3: 
    movl 8(%ebp),%eax  // %eax = arg1 
    movzbl (%eax),%eax  // %eax = *arg1 (zero-extend from byte to dword) 
    cmpb $1,%al   // *arg1 == 1? 

    je .L5 

    // *arg1 != 1 
    cmpl 12(%ebp),%eax  // arg2 == *arg1? 

    jne .L4 

    // *arg1 == arg2 
    movl $8,%eax   // result = 8 

.L5: leave 
    ret 

을, 우리 동일한 C 코드를 쓸 수 있습니다 :

int f(unsigned char *p, int v) 
{ 
    unsigned char b; 

    for(; (b = *p) != 1; p += 3) { 
     if(b == v) 
      return 8; 
    } 

    return b; 
}