스택을 떠날 때 자동으로 메모리를 비 웁니다.

Question

동적으로 할당 된 주소 공간의 포인터가 스택을 떠나 자마자 자동으로 메모리를 비울 수있는 프로그램을 작성하고 싶습니다. 예제는 다음과 같습니다

procedure FillMemory (var mypointer); 
begin 
    // CopyMemory, Move, etc... with data 
end; 

procedure MyProcedure; 
var 
    MyPointer : Pointer; 
begin 
    MyPointer := VirtualAlloc (NIL, 1024, MEM_COMMIT or MEM_RESERVE, PAGE_EXECUTE_READWRITE); 
    FillMemory (MyPointer); 
    VirtualFree(MyPointer, 0, MEM_RELEASE); // I would like to avoid this... 
end; 

내가 문자열을 사용할 수 있지만, 나 또한 그들을 피하기 위해 같은 것 (I 스택에 문자열 어쨌든 해방받을 경우 너무 잘 모르겠습니다 ...) 어떤 아이디어?

Answer 1

내 의견과 아리옥과 논의를 확장하려면

당신이 만약 단지 원시 메모리 블록을 원하면 동적 인 array of byte을 사용하십시오. 컴파일러는 메서드의 마지막에이 메모리를 해제하는 코드를 생성합니다.

type 
    TBytes = array of Byte; // omit for newer Delphi versions 

procedure FillMemory(var Bytes: TBytes); 
begin 
    { passing in here will increase the reference count to 2 } 
    // CopyMemory, Move, etc... with data 
end; // then drop back to 1 

procedure MyProcedure; 
var 
    Buffer : TBytes; 
begin 
    SetLength(Buffer, 1024); // buffer has reference count of 1 
    FillMemory (Buffer); 
end; // reference count will drop to 0, and Delphi will free memory here 

이 모든 것이 의미가 있기를 바랍니다. 자정입니다. 그래서 가장 깨어있는 느낌이 들지 않습니다 ...

Answer 2

관리되는 유형은 참조가 계산되고 계수가 0으로 떨어지면 완료됩니다. 지역 변수가 있으면 범위를 벗어나면 참조 카운트가 0으로 떨어집니다.

따라서 인터페이스를 사용하여 참조하는 TInterfacedObject의 하위 항목을 만들 수 있습니다. 이런 식으로 뭔가 :

이

type 
    TLifetimeWatcher = class(TInterfacedObject) 
    private 
    FDestroyProc: TProc; 
    public 
    constructor Create(const DestroyProc: TProc); 
    destructor Destroy; override; 
    end; 

constructor TLifetimeWatcher.Create(const DestroyProc: TProc); 
begin 
    inherited Create; 
    FDestroyProc := DestroyProc; 
end; 

destructor TLifetimeWatcher.Destroy; 
begin 
    if Assigned(FDestroyProc) then 
    FDestroyProc(); 
    inherited; 
end; 

당신은 다음과 같이 사용할 수는 :

LifetimeWatcher이 범위를 잎

procedure MyProcedure; 
var 
    MyPointer: Pointer; 
    LifetimeWatcher: IInterface; 
begin 
    MyPointer := VirtualAlloc (NIL, 1024, MEM_COMMIT or MEM_RESERVE, 
    PAGE_EXECUTE_READWRITE); 
    LifetimeWatcher := TLifetimeWatcher.Create(
    procedure 
    begin 
     VirtualFree(MyPointer, 0, MEM_RELEASE); 
    end; 
) 
    FillMemory(MyPointer); 
end; 

, 당신은 TLifetimeWatcher.Create에 전달 파괴 구현하는 객체와 절차가 실행됩니다.

이 아이디어를 유스 케이스 전용으로 전문화하는 것은 쉽습니다. 그러면 호출 사이트의 코드가 간결 해집니다.

과 같을 것이다

:

function VirtualAllocAutoRelease(Size: SIZE_T; Protect: DWORD; 
    out LifetimeCookie: IInterface): Pointer; 
var 
    Ptr: Pointer; 
begin 
    Ptr := VirtualAlloc(nil, Size, MEM_COMMIT or MEM_RESERVE, Protect); 
    Win32Check(Ptr<>nil); 
    LifetimeCookie := TLifetimeWatcher.Create(
    procedure 
    begin 
     VirtualFree(Ptr, 0, MEM_RELEASE); 
    end 
); 
    Result := Ptr; 
end; 

을 그리고 당신이처럼 사용하십시오 :

procedure MyProcedure; 
var 
    MyPointer: Pointer; 
    LifetimeWatcher: IInterface; 
begin 
    MyPointer := VirtualAllocAutoRelease(1024, PAGE_EXECUTE_READWRITE, 
    LifetimeWatcher); 
    FillMemory(MyPointer); 
end;