VBA에서 형식 라이브러리를 등록하는 방법

Question

Google (Subs RegisterTypeLibrary 및 RegisterTypeLibrary2 아래)을 사용하여 찾은 기술의 두 가지 변형을 사용하여 프로그래밍 방식으로 형식 라이브러리를 VBA 코드에서 등록하려고합니다.

아래 코드는 LoadTypeLib/LoadTypeLibEx 호출시 액세스 위반으로 인해 충돌합니다. 내가 도대체 ​​뭘 잘못하고있는 겁니까? 관련된 경우 유형 라이브러리는 tlbexp를 사용하여 .NET 어셈블리에서 생성 된 TLB 파일입니다.

Private Enum RegKind 
    RegKind_Default = 0 
    RegKind_Register = 1 
    RegKind_None = 2 
End Enum 

Private Declare Function LoadTypeLibEx Lib "oleaut32.dll" (_ 
    pFileName As Byte, ByVal RegKind As RegKind, pptlib As Object) As Long 
Private Declare Function LoadTypeLib Lib "oleaut32.dll" (_ 
    pFileName As Byte, pptlib As Object) As Long 
Private Declare Function RegisterTypeLib Lib "oleaut32.dll" (_ 
    ByVal ptlib As Object, szFullPath As Byte, _ 
    szHelpFile As Byte) As Long 

Private Sub RegisterTypeLibrary(FileName As String) 

    Dim abNullTerminatedFileName() As Byte 
    Dim objTypeLib As Object 
    Dim lHResult As Long 

    abNullTerminatedFileName = FileName & vbNullChar 
    lHResult = LoadTypeLib(abNullTerminatedFileName(0), objTypeLib) 
    If lHResult <> 0 Then 
     Err.Raise lHResult, "LoadTypeLib", "Error registering type library " & FileName 
    End If 
    lHResult = RegisterTypeLib(objTypeLib, abNullTerminatedFileName(0), 0) 
    If lHResult <> 0 Then 
     Err.Raise lHResult, "RegisterTypeLib", "Error registering type library " & FileName 
    End If 
    Exit Sub 

End Sub 
Private Sub RegisterTypeLibrary2(FileName As String) 
    Dim abNullTerminatedFileName() As Byte 
    Dim objTypeLib As Object 
    Dim lHResult As Long 

    abNullTerminatedFileName = FileName & vbNullChar 
    lHResult = LoadTypeLibEx(abNullTerminatedFileName(0), ByVal RegKind_Register, objTypeLib) 
    If lHResult <> 0 Then 
     Err.Raise lHResult, "LoadTypeLibEx", "Error registering type library " & FileName 
    End If 
End Sub 

편집

나는 내 형식 라이브러리에 대한 구체적인 무언가 생각한다. 아래에 답변으로 게시 한 솔루션을 발견했습니다.

Answer 1

아래 코드를 사용하여 해결책을 찾았습니다. 기본적으로 LoadTypeLibEx (C/C++의 ITypeLib **)에 대한 세 번째 매개 변수는 Object가 아닌 stdole.IUnknown로 선언됩니다.

이렇게하려면 stdole32.tlb에 대한 참조를 VBA 프로젝트에 추가해야했습니다.

VB (late-bound) 개체로 선언 할 수 없다는 것을 의미하는 내 형식 라이브러리에 대한 의구심이 있습니다.

또한 세 번째 매개 변수를 Long으로 선언 할 수도 있지만 참조 계산에 문제가 발생하지는 않을지는 확실하지 않습니다.

Private Enum RegKind 
    RegKind_Default = 0 
    RegKind_Register = 1 
    RegKind_None = 2 
End Enum 

Private Declare Function LoadTypeLibEx Lib "oleaut32.dll" (_ 
    pFileName As Byte, ByVal RegKind As RegKind, pptlib As stdole.IUnknown) As Long 

Public Sub RegisterTypeLibrary(FileName As String) 
    Dim abNullTerminatedFileName() As Byte 
    Dim objTypeLib As stdole.IUnknown 
    Dim lHResult As Long 

    abNullTerminatedFileName = FileName & vbNullChar 
    lHResult = LoadTypeLibEx(abNullTerminatedFileName(0), ByVal RegKind_Register, objTypeLib) 
    If lHResult <> 0 Then 
     Err.Raise lHResult, "LoadTypeLibEx", "Error registering type library " & FileName 
    End If 
End Sub 

Answer 2

타사 TLB에 대해 테스트했을 때 제공 한 코드가 작동하기 때문에 형식 라이브러리 (TLB)에 오류가있는 것으로 의심됩니다.

VBA에서 .NET 어셈블리를 사용한다고 가정합니다. 따라서 VBA에서 오류없이 TLB를 참조 할 수 있는지 확인하십시오.

.NET 라이브러리에 의해 노출 된 모든 개체에는 인수를 허용하지 않는 공용 생성자가 있어야합니다. 이로 인해 문제가 발생할 수 있습니다.