UIImage를 흐리게 처리하지만 날카로운 객체 경계를 유지하는 방법은 무엇입니까?

Question

내용이 흐려 지지만 가장자리가 선명하게 남아있는 UIImage에 "스마트"흐림 효과를 적용하고 싶습니다. 예를 들어

, 여기에 내 원래 이미지 :

여기이 흐림이 적용된 후 내가보고 싶은 것입니다 :

을 내가 할 수있는 방법 UIImage에서 이와 같은 "똑똑한"흐림 효과가 있습니까?

Answer 1

여기서 찾고있는 흐림 효과를 양면 흐림이라고합니다. 표준 가우시안 흐림 효과와는 달리 주변 픽셀 색상은 중앙 픽셀 색상과 중앙 픽셀과의 유사도를 기준으로 평균화됩니다. 이렇게하면 오브젝트의 내부 영역이 흐려 지지만 예리한 윤곽이 유지됩니다.

내 오픈 소스 GPUImage 프레임 워크에는 GPUImageBilateralFilter라는 필터가 있습니다. (1.0 blurSize 1.6의 distanceNormalizationFactor 사용) 이미지에 적용 할 때 그의 출력 :이 내 결과와 대상 사이에 약간의 차이가 있지만 그 인해 아마

내가 사용하는 구체적인 가중치. 여기에서 매개 변수를 조정하면 위의 내용과 더 가까워 질 수 있습니다.

을 OpenCV는 양자 흐림 필터를 가지고 있으며,이 프레임 워크의 외부를 사용하고 싶은 경우 당신은 나의 조각 쉐이더 소스 코드를 가지고 자신의 OpenGL ES 구현을 구성하려면이 옵션을 사용할 수 있습니다

uniform sampler2D inputImageTexture; 

const lowp int GAUSSIAN_SAMPLES = 9; 

varying highp vec2 textureCoordinate; 
varying highp vec2 blurCoordinates[GAUSSIAN_SAMPLES]; 

uniform mediump float distanceNormalizationFactor; 

void main() 
{ 
    lowp vec4 centralColor; 
    lowp float gaussianWeightTotal; 
    lowp vec4 sum; 
    lowp vec4 sampleColor; 
    lowp float distanceFromCentralColor; 
    lowp float gaussianWeight; 

    centralColor = texture2D(inputImageTexture, blurCoordinates[4]); 
    gaussianWeightTotal = 0.18; 
    sum = centralColor * 0.18; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[0]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.05 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[1]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.09 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[2]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.12 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[3]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.15 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[5]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.15 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[6]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.12 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[7]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.09 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    sampleColor = texture2D(inputImageTexture, blurCoordinates[8]); 
    distanceFromCentralColor = min(distance(centralColor, sampleColor) * distanceNormalizationFactor, 1.0); 
    gaussianWeight = 0.05 * (1.0 - distanceFromCentralColor); 
    gaussianWeightTotal += gaussianWeight; 
    sum += sampleColor * gaussianWeight; 

    gl_FragColor = sum/gaussianWeightTotal; 
}