런타임 오류 (1004)는 정렬 기능 VBA

Question

는 내가이 코드 덩어리를 실행할 때 절반의 시간에 대한 오류 1004을 받고있는 것으로 보인다 나는 이유는 전혀 확실하지 않다 : 코드가 실행되고이

Dim ranged As Range 
Set ranged = Range("AJ2") 
Set ranged = Range(ranged, ranged.End(xlDown)) 


Sheets(i).Select 
ActiveWorkbook.Worksheets(i).Sort.SortFields.Add Key:=ranged, _ 
    SortOn:=xlSortOnValues, Order:=xlDescending, DataOption:=xlSortNormal 
With ActiveWorkbook.Worksheets(i).Sort 
    .SetRange ranged 
    .Header = xlNo 
    .MatchCase = False 
    .Orientation = xlTopToBottom 
    .SortMethod = xlPinYin 
    .Apply 

End With 

을 일련의 워크 시트에서 열 AJ의 범위는 각 시트의 크기가 다르기 때문에 시작시 범위 정의가 필요합니다. 목표는 범위의 순서를 뒤집는 것입니다. 누구든지 오류가 여기에 무엇을 도와 드릴까요?

Answer 1

1. 대부분의 경우 워크 시트를 선택할 필요가 없습니다. 참조 할 수도 있습니다 THIS

2. 범위를 구성하는 데 xlDown을 사용하지 마십시오. xlUp을 사용하여 데이터가있는 마지막 행을 찾아서 수행하십시오. 당신이보고 싶어 할 수도 있습니다 THIS

위의 두 가지를 모두 합치면, 코드는 다음과 같을 수 있습니다. 그것을 시도하십시오. (안된)

Dim ranged As Range 
Dim lRow As Long 

' 
'~~> Rest of the code 
' 

With ThisWorkbook.Sheets(i) 
    '~~> Find Last row in Col AJ which has data 
    lRow = .Range("AJ" & .Rows.Count).End(xlUp).Row 

    '~~> Construct your range 
    Set ranged = .Range("AJ2:AJ" & lRow) 

    '~~> Sort 
    .Sort.SortFields.Add Key:=ranged, _ 
         SortOn:=xlSortOnValues, _ 
         Order:=xlDescending, _ 
         DataOption:=xlSortNormal 
    With .Sort 
     .SetRange ranged 
     .Header = xlNo 
     .MatchCase = False 
     .Orientation = xlTopToBottom 
     .SortMethod = xlPinYin 
     .Apply 
    End With 
End With 

' 
'~~> Rest of the code 
' 

시도하고 테스트 완료 VERSION 도와

Sub Sample() 
    Dim ranged As Range 
    Dim lRow As Long, i As Long 

    For i = 1 To ThisWorkbook.Sheets.Count 
     ' 
     '~~> Rest of the code 
     ' 

     With ThisWorkbook.Sheets(i) 
      '~~> Find Last row in Col AJ which has data 
      lRow = .Range("AJ" & .Rows.Count).End(xlUp).Row 

      '~~> Construct your range 
      Set ranged = .Range("AJ2:AJ" & lRow) 

      '~~> Sort 
      .Sort.SortFields.Add Key:=ranged, _ 
           SortOn:=xlSortOnValues, _ 
           Order:=xlDescending, _ 
           DataOption:=xlSortNormal 
      With .Sort 
       .SetRange ranged 
       .Header = xlNo 
       .MatchCase = False 
       .Orientation = xlTopToBottom 
       .SortMethod = xlPinYin 
       .Apply 
      End With 
     End With 

     ' 
     '~~> Rest of the code 
     ' 
    Next i 
End Sub