셀 내용을 여러 셀로 바꾸기

Question

셀을 여러 셀로 바꾸고 다른 셀을 여러 셀로 대체하는 방법이 있습니까? 다음의 예는 시트 (A)의 제 1 라인의 교체를 도시

워크 시트 A : 열 A의 항목이 해당 항목으로 대체되어야 워크 B의 대체 논리

어디에서나 zd가 사용되면 a_zd, b_zd 및 y_zd가되어야합니다. 어디에서나 fs가 사용되면 c_fs, y_fs 및 z_fs가되어야합니다. 예 : A1 = zd 및 B1 = a_zd; A2 = zd 및 B2 = b_zd; A3 = zd 및 B3 = y_zd; A4 = fs 및 B4 = c_fs; A5 = fs 및 B5 = y_fs; A6에서의 = FS 및 B6 = z_fs : 워크 C. 예의 결과를 가질 것이다

워크 A의 제 1 라인의 교체 : A1 = B1 = a_zd 및 c_fs; A2 = a_zd 및 B2 = y_fs; A3 = a_zd 및 B3 = z_fs; A4 = b_zd 및 B4 = c_fs; A5 = b_zd 및 B5 = y_fs; A6 = b_zd 및 B6 = z_fs; A7 = y_zd 및 B7 = c_fs; A8 = y_zd 및 B8 = y_fs; A9 = y_zd 및 B9 = z_fs ;:

Answer 1

Option Explicit 

Sub CombineData() 
    Dim myInput As Range 
    Dim myOutput As Range 
    Dim inputTwoValues As Collection 
    Dim output1 As Collection 
    Dim output2 As Collection 
    Dim anOutput1 As Variant 
    Dim anOutput2 As Variant 

    Set myInput = Worksheets("Sheet1").Range("A1") 
    Set myOutput = Worksheets("Sheet3").Range("A1") 

    Do 
     Set output1 = GetRelatedValues(myInput.Value) 
     Set output2 = GetRelatedValues(myInput.Offset(0, 1).Value) 
     For Each anOutput1 In output1 
      For Each anOutput2 In output2 
       myOutput.Formula = anOutput1 
       myOutput.Offset(0, 1).Formula = anOutput2 
       Set myOutput = myOutput.Offset(1, 0) 
      Next 
     Next 
     Set myInput = myInput.Offset(1, 0) 
    Loop While myInput.Value <> "" 
End Sub 


Function GetRelatedValues(myInput As Variant) As Collection 
    Dim returnVal As New Collection 
    Dim myRelationship As Range 
    Set myRelationship = Worksheets("Sheet2").Range("A1") 

    While myRelationship.Value <> "" 
     If myRelationship.Value = myInput Then 
      returnVal.Add (myRelationship.Offset(0, 1).Value) 
     End If 
     Set myRelationship = myRelationship.Offset(1, 0) 
    Wend 
    Set GetRelatedValues = returnVal 
End Function