VB를 사용하여 Excel transpose

Question

Excel에서 큰 데이터를 표시하기 위해 VB를 사용하고 있습니다. 그들은 A1 : A3000에 나타납니다. 나는 A1을 전치하고 있습니다 : A6를 B1에 : G1은이 코드를 사용 :

sheet.Range("A1:A6").Copy() 
sheet.Range("B1").PasteSpecial(Transpose:=True) 

그것은 일하고있어하지만 난 A3000 개까지이 과정을 반복에 대한 문제에 직면하고있다. 기본적으로 나는 1 열 x3000 행 데이터를 6 열 x 500 행 데이터로 변환하려고합니다. 즉, 최종 결과는 500 행과 열이 있어야합니다. B : G.

Answer 1

이 기능이 작동합니까?

Sub Test() 
    Dim R1 As Long, R2 As Long, C2 As Long 
    R2 = 1 
    C2 = 2 
    For R1 = 1 To ActiveSheet.UsedRange.Rows.Count 
    Cells(R2, C2) = Cells(R1, 1) 
    If C2 < 7 Then 
     C2 = C2 + 1 
    Else 
     R2 = R2 + 1 
     C2 = 2 
    End If 
    Next R1 
End Sub 

Answer 2

코드는 VBA에 있습니다. 대신 복사/붙여 넣기를하는
는, 상기 범위의 함량 (즉 어레이)의 실제 코드

Option Explicit 

Sub Tabulate(ByVal src As Range, ByVal splitSize As Integer, _ 
ByVal destRangeStart As Range) 
Dim i As Integer 
Dim rangeToCopy As Range 
Dim rangeToPasteOver As Range 

Set rangeToCopy = src 
Set rangeToPasteOver = destRangeStart 

Debug.Print Now 
Application.ScreenUpdating = False 
For i = 1 To src.Cells.Count Step splitSize 
' rangeToCopy.Resize(splitSize).Copy 
' rangeToPasteOver.PasteSpecial Transpose:=True 

    rangeToPasteOver.Resize(ColumnSize:=splitSize).Value = _ 
     Transform2DArray(rangeToCopy.Resize(splitSize).Value) 

    Set rangeToCopy = rangeToCopy.Offset(splitSize) 
    Set rangeToPasteOver = rangeToPasteOver.Offset(1) 
Next 
Application.ScreenUpdating = True 

Debug.Print Now 
End Sub 
Function Transform2DArray(ByVal src As Variant) As Variant 
Dim returnValue As Variant 

Dim rowCtr As Long 
Dim colCtr As Long 

Dim destColCtr As Long 
Dim destRowCtr As Long 


Dim lRows As Long 
Dim uRows As Long 

Dim lCols As Long 
Dim uCols As Long 

lRows = LBound(src, 1) 
uRows = UBound(src, 1) 

lCols = LBound(src, 2) 
uCols = UBound(src, 2) 

ReDim returnValue(lCols To uCols, lRows To uRows) 

destRowCtr = lCols 

For colCtr = lCols To uCols 
    destColCtr = lRows 
    For rowCtr = lRows To uRows 
     returnValue(destRowCtr, destColCtr) = src(rowCtr, colCtr) 
     destColCtr = destColCtr + 1 
    Next 
    destRowCtr = destRowCtr + 1 
Next 

Transform2DArray = returnValue 
End Function