다른 셀의 값을 기준으로 셀 잠그기

Question

아래 코드를 찾으십시오. 내 코드에서 어디서 잘못 될지 모르겠습니다. 본인의 목적은 D44 셀 (드롭 다운 목록)의 값을 확인하고 D45 셀의 잠금/잠금 해제 값을 기준으로합니다. D44에서

값은 NO없고, 13 fracto, 18 fracto 다른 어떤 Fracto "모든 다른 Fracto" 사용자가 D44 셀의 값에 설정되어있는 경우에만 셀 D45을 편집 할 수 있어야한다 ".

Sub TheSelectCase() 
    Select Case Range("D44").Value 
      Case "Any Other Fracto" 
      Range("D45").Locked = False 
      Range("D45").Activate 

      Case = "NO" 
      Range("D45").Locked = True 
     Range("D45").Clear 

     Case <> "NO" Or "Any Other Fracto" 
     Range("D45").Locked = True 
    End Select 
End Sub 

Answer 1

드롭 다운이 ActiveX 컨트롤이 아닌 한 Worksheet_Change 이벤트 핸들러를 통해이 작업을 수행해야하며 다음과 같은 두 가지 경우만 있습니다. 1) 사용자가 편집 할 수있는 경우 ('기타 모든 프랙 터')와 2) 사용자가 편집 할 수없는 다른 값

유효성 검사 목록은 워크 시트의 Worksheet_Change 이벤트에서 수행하십시오.

Private Sub Worksheet_Change(ByVal Target As Range) 

    'Exit on any other cell 
    If Intersect(Target, Range("D44")) Is Nothing Then Exit Sub 
    Application.EnableEvents = False 
    Dim inputCell As Range 
    Set inputCell = Range("D45") 
     Select Case Trim(LCase(Target.Value)) 
      Case "any other fracto" 
       inputCell.Locked = False 
       inputCell.Activate 
      Case Else 
      'This handles **ANY** other value in the dropdown 
       inputCell.Locked = True 
       InputCell.Clear 
     End Select 

    Application.EnableEvents = True 
End Sub