SQL 서버 문자열 문자열은

Question

나는 문자열을 가지고있다.

d

는 변수이므로 1, 3, 20, 될 수 ... 등

나는 D의 값을 알고 있지만, 제가 모르는의 문자열을 얻는 방법이다 원래 문자열 d 용어입니다.

나는이 시도 :

@L = '' 
SET @ColumnNo = 0 
WHILE @ColumnNo <= @d 
BEGIN 
    SET @L = @L + ' ' + SUBSTRING(@TempCol, 1, CHARINDEX(',',@TempCol)-1) 
    SET @TempCol = REPLACE (@TempCol, LTRIM(RTRIM(@L)) ,'') 
    Set @ColumnNo = @ColumnNo + 1 
    PRINT @L 
END 

을하지만 예상되는 결과를 얻을하는 방법을 모르겠어요.

Answer 1

DECLARE @TempCol varchar(max), @d int, @p int, @Result varchar(max); 
SET @TempCol = 'item1,item2,itemA,itemB,item#,item$'; 
SET @d = 3; 

SET @p = 1; 

WHILE @d > 0 AND @p > 0 BEGIN 
    SET @p = CHARINDEX(',', @TempCol, @p); 
    IF @p > 0 SET @p = @p + 1; 
    SET @d = @d - 1; 
END; 

IF @p = 0 
    SET @Result = @TempCol 
ELSE 
    SET @Result = SUBSTRING(@TempCol, 1, @p - 2); 

SELECT @Result; 

기본적으로, 루프 그냥 검색을 자를 최종 위치. 루프는 이후에 부분 문자열이 으로 추출됩니다.

@d을 너무 크게 지정하면 결과는 모두 @TempCol이되며, 그렇지 않은 경우 원하는 수의 항목이 생성됩니다.

Answer 2

필요한 기능은 분할 기능입니다 (하단에 표시). 주어진 점에 조립 된 문자열을 원하는 경우

With SplitItems As 
    (
    Select Position, Value 
     , Row_Number() Over (Order By Position) As ItemNum 
    From dbo.udf_Split(@TempCol, ',') 
    ) 
Select Value 
From SplitItems 
Where ItemNum <= @d 

당신은 간단 할 것 :

With SplitItems As 
    (
    Select Position, Value 
     , Row_Number() Over (Order By Position) As ItemNum 
    From dbo.udf_Split(@TempCol, ',') 
    ) 
Select ',' + Value 
From SplitItems 
Where ItemNum <= @d 
Order By ItemNum 
For Xml Path('') 

분할 기능 :

SET ANSI_NULLS ON 
GO 
SET QUOTED_IDENTIFIER ON 
GO 
Create FUNCTION [dbo].[udf_Split] 
( 
    @DelimitedList nvarchar(max) 
    , @Delimiter nvarchar(2) = ',' 
) 
RETURNS TABLE 
AS 
RETURN 
    (
    With CorrectedList As 
     (
     Select Case When Left(@DelimitedList, Len(@Delimiter)) <> @Delimiter Then @Delimiter Else '' End 
      + @DelimitedList 
      + Case When Right(@DelimitedList, Len(@Delimiter)) <> @Delimiter Then @Delimiter Else '' End 
      As List 
      , Len(@Delimiter) As DelimiterLen 
     ) 
     , Numbers As 
     (
     Select TOP(Coalesce(DataLength(@DelimitedList)/2,0)) Row_Number() Over (Order By c1.object_id) As Value 
     From sys.columns As c1 
      Cross Join sys.columns As c2 
     ) 
    Select CharIndex(@Delimiter, CL.list, N.Value) + CL.DelimiterLen As Position 
     , Substring (
        CL.List 
        , CharIndex(@Delimiter, CL.list, N.Value) + CL.DelimiterLen  
        , CharIndex(@Delimiter, CL.list, N.Value + 1)       
         - (CharIndex(@Delimiter, CL.list, N.Value) + CL.DelimiterLen) 
        ) As Value 
    From CorrectedList As CL 
     Cross Join Numbers As N 
    Where N.Value <= DataLength(CL.List)/2 
     And Substring(CL.List, N.Value, CL.DelimiterLen) = @Delimiter 
    )