Access VBA get Cancel 속성에 대해 Sub에 데이터를 전달하는 함수

Question

폼에 날짜가 있으며 각각을 개별적으로 확인하기 시작했습니다. 이 모든 수표를 각각의 'before update'이벤트에서 호출 할 수있는 하나의 함수로 바꾸고 싶었습니다. 문제는 유효성 검사가 실패 할 때 컨트롤에 포커스를 유지할 수 없다는 것입니다.

Public Function CheckDate(datefield As TextBox) As Integer 

Dim this_date As Date 
Dim DOB As Date 
Dim first_seen As Date 
this_date = Conversion.CDate(datefield.text) 
DOB = [Forms]![generic]![date_of_birth] 
first_seen = [Forms]![generic]![date_first_seen] 

If Not IsNull(this_date) Then 
    'date of birth must precede any other date 
    If this_date < DOB Then 
     MsgBox "This date precedes the date of birth", vbExclamation, "Invalid date" 
     CheckDate = -1 
     Exit Function 
    End If 
    'date can't be in the future 
    If this_date > DateTime.Date Then 
     MsgBox "This date is in the future", vbExclamation, "Invalid date" 
     CheckDate = -1 
     Exit Function 
    End If 
    'all investigation/treatment dates must be >= date first seen 
    If Not IsNull(first_seen) Then 
     If this_date < first_seen Then 
      MsgBox "This date precedes the date patient was first seen", vbExclamation, "Invalid date" 
      CheckDate = -1 
      Exit Function 
     End If 
    End If 
End If 

End Function 

은

Private Sub xray_date_BeforeUpdate(Cancel As Integer) 

내에서 나는 시도했다 : 올바른 메시지를 표시하지만, 이동 편집을 위해 거기를 유지하는 대신 컨트롤에서 초점

Call CheckDate(xray_date) 

.

Cancel = CheckDate(xray_date) 

은 무언가를 수행하는 것으로 보이지 않으므로 잘못된 데이터를 저장 장치로 전달할 수 있습니다. 그렇다면 유효성 검사가 실패 할 때 BeforeUpdate의 Cancel 이벤트를 True로 설정하려면 어떤 식으로 함수를 호출해야합니까?

Answer 1

샘플 코드를 이해하는 데 어려움을 겪었으므로 날짜/시간 필드가있는 테이블을 만들었습니다. date_of_birth; date_first_seen; 및 xray_date. 그런 다음 해당 텍스트 상자가 해당 필드에 바인딩 된 테이블을 기반으로 양식을 작성했습니다. txtDate_of_birth; txtDate_first_seen; 및 txtXray_date.

이것은 내 양식의 코드 모듈이며 AFAICT는 txtXray_date의 유효성을 검사합니다.

Option Compare Database 
Option Explicit 

Private Function CheckDate(ctlDate As TextBox) As Integer 
    Const clngChecks As Long = 3 ' change this to match the number 
           ' of conditions in the For loop 
    Const cstrTitle As String = "Invalid date" 
    Dim i As Long 
    Dim intReturn As Integer 
    Dim lngButtons As Long 
    Dim strPrompt As String 
    Dim strTitle As String 

    lngButtons = vbExclamation 
    strPrompt = vbNullString ' make it explicit 
    intReturn = 0 ' make it explicit 

    For i = 1 To clngChecks 
     Select Case i 
     Case 1 
      'date of birth must precede any other date 
      If ctlDate < Me.txtDate_of_birth Then 
       strPrompt = "This date precedes the date of birth" 
       Exit For 
      End If 
     Case 2 
      'date can't be in the future 
      If ctlDate > DateTime.Date Then 
       strPrompt = "This date is in the future" 
       Exit For 
      End If 
     Case 3 
      'all investigation/treatment dates must be >= date first seen 
      If ctlDate < Me.txtDate_first_seen Then 
       strPrompt = "This date precedes the date patient was first seen" 
       Exit For 
      End If 
     End Select 
    Next i 

    If Len(strPrompt) > 0 Then 
     MsgBox strPrompt, lngButtons, cstrTitle 
     intReturn = -1 
    End If 
    CheckDate = intReturn 
End Function 

Private Sub txtXray_date_BeforeUpdate(Cancel As Integer) 
    Cancel = CheckDate(Me.txtXray_date) 
End Sub